תחילת העבודה עם IMA DAI SDK

ערכות ה-SDK של IMA מאפשרות לשלב בקלות מודעות מולטימדיה באתרים ובאפליקציות שלכם. ערכות ה-SDK של IMA יכולות לבקש מודעות מכל שרת מודעות שתואם ל-VAST ולנהל את ההפעלה של המודעות באפליקציות. באמצעות ערכות ה-SDK של IMA DAI, האפליקציות שולחות בקשה לשידור של מודעת וידאו ותוכן וידאו – VOD או תוכן בשידור חי. לאחר מכן, ה-SDK מחזיר שידור וידאו משולב, כך שלא תצטרכו לנהל את המעבר בין סרטון המודעה לסרטון התוכן באפליקציה.

בחירת פתרון ה-DAI הרצוי

שירות מלא הצגת פוד

במדריך הזה מוסבר איך להפעיל מודעות דינמיות (DAI) ב-Pod שמציג שידור חי או VOD, באמצעות IMA DAI SDK ל-Roku. כדי להציג או לפעול לפי שילוב לדוגמה שכבר הושלם, תוכלו להוריד את הדוגמה של Pod Serving.

הערה: IMA DAI SDK ל-Roku תומך גם בסטרימינג HLS וגם בסטרימינג DASH, ללא הבדלים בהטמעה.

כדי להשתמש ב-IMA DAI, צריך חשבון Ad Manager 360 Advanced. אם יש לכם חשבון Ad Manager, תוכלו לפנות למנהל החשבון לקבלת פרטים נוספים. מידע נוסף על ההרשמה ל-Ad Manager זמין במרכז העזרה של Ad Manager.

הערה: מידע על שילוב עם פלטפורמות אחרות או על שימוש ב-SDK של IMA בצד הלקוח זמין במאמר ערכות SDK של מודעות אינטראקטיביות לווידאו.

סקירה כללית על הצגת מודעות ב-IMA DAI Pod

כדי להטמיע הצגת מודעות ברצף באמצעות IMA DAI, צריך להשתמש בשני רכיבי SDK עיקריים, שמתוארים במדריך הזה:

• StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest(): יצירת אובייקט שמגדיר בקשת סטרימינג לשרתים של Google לצורכי פרסום. הבקשות האלה כוללות קוד רשת, וגם מפתח נכס מותאם אישית ומפתח API אופציונלי ל-Pod Live ima.StreamRequest.
• StreamManager: אובייקט שמטפל בתקשורת בין סטרימינג הווידאו לבין IMA DAI SDK, למשל הפעלת פינגים למעקב והעברת אירועי סטרימינג לבעלי האפליקציה.

בנוסף, צריך לשלוח בקשה לשרת מניפולציית המניפסט כדי לאחזר את המניפסט של הסטרימינג ולהציג אותו באפליקציה. התהליך המדויק עשוי להשתנות בהתאם ל-VTP (שותף טכנולוגיית וידאו).

חשוב: לצורך המדריך הזה, נניח ששרת מניפולציית המניפסט מצפה לבקשת GET עם מזהה הסטרימינג שמוענק כמשתנה שאילתה. משתמשים במאקרו [[STREAMID]] כתופס בכתובת ה-URL של הבקשה, ומחליפים אותו במזהה הסטרימינג לפני שליחת הבקשה. השרת לטיפול במניפסט יכול להיות שונה.

דרישות מוקדמות

• כדאי לעיין בדף התאימות כדי לוודא שהתרחיש לדוגמה שלכם נתמך.
• הורדת קוד נגן לדוגמה ל-Roku.
• פורסים את קוד הנגן לדוגמה במכשיר Roku כדי לוודא שההגדרה של סביבת הפיתוח פועלת.

הפעלת הסרטון

נגן הווידאו לדוגמה שסופק מאפשר להפעיל סרטון תוכן באופן מובנה. פורסים את הנגן לדוגמה במכשיר Roku כדי לוודא שסביבת הפיתוח מוגדרת כראוי.

איך הופכים את נגן הווידאו לנגן סטרימינג של IMA DAI

כדי להטמיע נגן סטרימינג, פועלים לפי השלבים הבאים.

יצירת Sdk.xml

מוסיפים קובץ חדש לפרויקט לצד MainScene.xml בשם Sdk.xml, ומוסיפים את הטקסט הבא:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

לאורך המדריך הזה תצטרכו לערוך את שני הקבצים האלה (MainScene.xml ו-Sdk.xml).

טעינת המסגרת של IMA DAI SDK

כדי לטעון את המסגרת, מוסיפים את הטקסט הבא לקובצי manifest ו-Sdk.xml:

manifest

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

אתחול ה-IMA DAI SDK

השלב הראשון בחיבור של הטמעת המודעות הדינמיות של IMA הוא טעינת ה-IMA DAI SDK והפעלה שלו. הקוד הבא מאתחלל את הסקריפט של IMA DAI SDK.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

עכשיו מתחילים את המשימה הזו ב-MainScene.xml ומסירים את הקריאה לטעון את מקור התוכן.

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

יצירת נגן סטרימינג של IMA

בשלב הבא, צריך להשתמש ב-roVideoScreen הקיים כדי ליצור נגן של שידור IMA.

הצגת מודעות ברצף של שידורים חיים

בשידורים חיים, נגן הסטרימינג הזה מטמיע שלוש שיטות קריאה חוזרת (callbacks): streamInitialized,‏ adBreakStarted ו-adBreakEnded.

צריך גם להשבית את האפשרות להפעלה מהירה כשהשידור נטען. כך המשתמשים לא יוכלו לדלג על מודעה לפני הסרטון ברגע שהיא מתחילה, לפני שהאירוע 'הפסקת הפרסום התחילה' מופעל.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

הצגת מודעות ב-Pod של שידור VOD

בשידורי VOD, נגן הסטרימינג הזה מטמיע ארבע שיטות קריאה חוזרת (callback): streamInitialized,‏ loadUrl,‏ adBreakStarted ו-adBreakEnded. בקריאה החוזרת streamInitialized, חשוב להתקשר למספר StreamManager.loadThirdPartyStream(). אם לא תעשו זאת, ה-SDK לא יפעיל את הפונקציה loadUrl.

בשלב הזה, מבקשים גם כתובת URL של סטרימינג משותף טכנולוגיית הווידאו (VTP) עם מזהה סטרימינג שהתקבל ב-loadAdPodStream(). לאחר מכן, צריך להפעיל את StreamManager.loadThirdPartyStream() עם המניפסט של רצף המודעות וכל הכתוביות שהוחזרו על ידי ה-VTP.

צריך גם להשבית את האפשרות להפעלה מהירה כשהשידור נטען. כך המשתמשים לא יוכלו לדלג על מודעה לפני הסרטון ברגע שהיא מתחילה, לפני שהאירוע 'הפסקת הפרסום התחילה' מופעל.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

יצירת בקשה להפעלת סטרימינג של מודעות ברצף (pod) בשידור חי או ב-VOD והפעלתה

אחרי שיוצרים נגן סטרימינג, אפשר ליצור ולבצע בקשת סטרימינג. בדוגמה הזו מוצגים נתונים של מקור נתונים מסוג Pod Serving שמאוחסנים ב-m.testPodServingStream.

הצגת מודעות ברצף של שידורים חיים

באובייקט m.testPodServingStream, שומרים את הפרמטרים ש-Google Ad Manager צריך כדי לזהות את הסטרימינג הרלוונטי, כמו קוד רשת ומפתח נכס מותאם אישית. צריך גם לאחסן את כתובת ה-URL של המניפסט שמשמשת לגישה לשרת של מניפולציית המניפסט. במקרה כזה, צריך להוסיף את מזהה מקור הנתונים של Google לכתובת ה-URL של המניפסט אחרי שהבקשה להפעלת מקור הנתונים מוחזרת.

כדי לתמוך ב-AdUI, כמו סמלי AdChoices, צריך גם להעביר הפניה לצומת שמכיל את סרטון התוכן שלכם כחלק מהבקשה.

הערה: הפרמטרים של הסטרימינג שצוינו מיועדים לשידור של פודקאסט בשידור חי. כדי לבדוק עם שידור VOD של פודקאסט, צריך לספק פרמטרים משלכם לשידור הבדיקה.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

הצגת מודעות ב-Pod של שידור VOD

באובייקט m.testPodServingStream, יאוחסן קוד הרשת ששימש בבקשה להעברת הנתונים, כדי שמערכת Google Ad Manager תוכל לספק מזהה של מקור הנתונים. בנוסף, שומרים את כתובת ה-URL של המניפסט שמשמש לגישה למניפסט הספציפי למשתמש בשרת של מניפולציית המניפסט.

כדי לתמוך ב-AdUI, כמו סמלי AdChoices, צריך גם להעביר הפניה לצומת שמכיל את סרטון התוכן שלכם כחלק מהבקשה.

הערה: כדי לבדוק את ההטמעה של שידור ה-VOD, תצטרכו לספק את קוד הערוץ ואת כתובת ה-URL של המניפסט שלכם.

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

הוספת פונקציות מעקב אירועים והפעלת הסטרימינג

הצגת מודעות ברצף של שידורים חיים

אחרי ששולחים את הבקשה להפעלת הסטרימינג, צריך לבצע רק כמה פעולות: להוסיף מאזינים לאירועים כדי לעקוב אחרי התקדמות הצגת המודעה ולהעביר הודעות מ-Roku ל-SDK. חשוב להעביר את כל ההודעות ל-SDK כדי להבטיח הפעלה נכונה של המודעות. אם לא תעשו זאת, המערכת תדווח בצורה שגויה על צפיות במודעות.

בשלב הזה מוסיפים גם פונקציה שתחליף את המאקרו [[STREAMID]] במזהה הסטרימינג, ותעביר את כתובת ה-URL של הבקשה המלאה למניפסט לנגן הווידאו. בהטמעה הזו, מזהה הסטרימינג מקבלים בשלב הזה, אבל בהתאם לשילוב של VTP, יכול להיות שהוא יהיה זמין לפני השלב הזה.

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

הצגת מודעות ב-Pod של שידור VOD

אחרי ששולחים את הבקשה להפעלת הסטרימינג, צריך לבצע רק כמה פעולות: להוסיף מאזינים לאירועים כדי לעקוב אחרי התקדמות הצגת המודעה ולהעביר הודעות מ-Roku ל-SDK. חשוב להעביר את כל ההודעות ל-SDK כדי להבטיח הפעלה תקינה של המודעות. אם לא תעשו זאת, המערכת לא תדווח בצורה תקינה על צפיות במודעות.

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub