IMA SDK आपकी वेबसाइटों और ऐप्लिकेशन में मल्टीमीडिया विज्ञापनों को इंटिग्रेट करना आसान बनाते हैं. IMA SDK, किसी भी VAST का पालन करने वाले विज्ञापन सर्वर से विज्ञापनों का अनुरोध कर सकते हैं. साथ ही, आपके ऐप्लिकेशन में विज्ञापन चलाने की सुविधा को मैनेज कर सकते हैं. IMA डीएआई SDK टूल की मदद से, ऐप्लिकेशन विज्ञापन और कॉन्टेंट के लिए स्ट्रीम का अनुरोध करते हैं, फिर चाहे वह वीओडी (वीडियो ऑन डिमांड) हो या लाइव. इसके बाद, SDK टूल एक साथ कई वीडियो स्ट्रीम दिखाता है, ताकि आपको अपने ऐप्लिकेशन में विज्ञापन और कॉन्टेंट वीडियो के बीच स्विच करने का काम मैनेज न करना पड़े.
अपनी पसंद का डीएआई सलूशन चुनें
इस गाइड में Roku के लिए IMA डीएआई SDK टूल का इस्तेमाल करके, डीएआई पॉड सर्विंग को लाइव या वीओडी स्ट्रीम चलाने का तरीका बताया गया है.
IMA डीएआई पॉडकिंग के बारे में खास जानकारी
IMA डीएआई का इस्तेमाल करके पॉड सर्विंग को लागू करने के लिए, SDK टूल के दो मुख्य कॉम्पोनेंट शामिल करें. इनकी जानकारी इस गाइड में दी गई है:
StreamRequest.createPodLiveStreamRequest()
/StreamRequest.createPodVodStreamRequest()
: एक ऐसा ऑब्जेक्ट बनाता है जो Google के विज्ञापन सर्वर को स्ट्रीम करने के अनुरोध के बारे में जानकारी देता है. इन अनुरोधों के लिए एक नेटवर्क कोड तय करना होता है. साथ ही, Pod Liveima.StreamRequest
को भी कस्टम ऐसेट कुंजी और वैकल्पिक एपीआई पासकोड की ज़रूरत होती है.StreamManager
: एक ऐसा ऑब्जेक्ट जो वीडियो स्ट्रीम और IMA डीएआई SDK टूल के बीच कम्यूनिकेशन को मैनेज करता है. जैसे, पब्लिशर को ट्रैकिंग पिंग और स्ट्रीम इवेंट फ़ॉरवर्ड करना.
इसके अलावा, आपको अपने ऐप्लिकेशन के लिए स्ट्रीम मेनिफ़ेस्ट को फिर से पाने के लिए, अपने मेनिफ़ेस्ट में बदलाव करने वाले सर्वर से अनुरोध करना होगा. पूरी प्रोसेस में, वीडियो टेक्नोलॉजी पार्टनर (वीटीपी) और वीटीपी अलग-अलग हो सकते हैं.
ज़रूरी शर्तें
- हमारे साथ काम करने के तरीके पेज को पढ़ें और पक्का करें कि आपको जिस मकसद से इस्तेमाल का उदाहरण चाहिए वह काम करता है या नहीं.
- हमारा Roku सैंपल प्लेयर कोड डाउनलोड करें.
- यह पुष्टि करने के लिए कि आपका डेवलपमेंट सेट अप काम कर रहा है, सैंपल प्लेयर कोड को Roku डिवाइस पर डिप्लॉय करें.
अपना वीडियो चलाएं
सैंपल वीडियो प्लेयर की मदद से, अलग-अलग तरह के कॉन्टेंट वाले वीडियो देखे जा सकते हैं. अपने Roku डिवाइस पर सैंपल प्लेयर को डिप्लॉय करें. इससे यह पक्का किया जा सकेगा कि आपका डेवलपमेंट एनवायरमेंट सही तरीके से सेट अप किया गया है.
अपने वीडियो प्लेयर को IMA डीएआई स्ट्रीम प्लेयर में बदलें
स्ट्रीम प्लेयर लागू करने के लिए, यह तरीका अपनाएं.
Sdk.xml बनाएं
अपने प्रोजेक्ट में MainScene.xml
के साथ Sdk.xml
नाम की एक नई फ़ाइल जोड़ें और यह बॉयलरप्लेट जोड़ें:
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
आपको इस पूरी गाइड में, इन दोनों फ़ाइलों (MainScene.xml
और Sdk.xml
) में बदलाव करना होगा.
IMA डीएआई SDK टूल का फ़्रेमवर्क लोड करें
फ़्रेमवर्क लोड करने के लिए, manifest
और Sdk.xml
में यह जानकारी जोड़ें:
मेनिफ़ेस्ट
bs_libs_required=googleima3
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
Library "IMA3.brs"
]]>
</script>
</component>
IMA डीएआई SDK टूल शुरू करें
IMA डाइनैमिक ऐड इंसर्शन स्ट्रीम को लोड करने के लिए, सबसे पहले IMA डीएआई SDK टूल को लोड करना शुरू करें. नीचे दिए गए निर्देशों की मदद से, IMA डीएआई SDK टूल की स्क्रिप्ट शुरू होती है.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
<script type = "text/brightscript">
<![CDATA[
Library "IMA3.brs"
sub init()
m.top.functionName = "runThread"
end sub
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
end sub
sub initializeIMASDK()
if m.sdk = invalid
m.sdk = New_IMASDK()
end if
m.top.IMASDKInitialized = true
end sub
]]>
</script>
</component>
अब MainScene.xml
में यह टास्क शुरू करें और कॉन्टेंट स्ट्रीम लोड करने के लिए, इस टास्क को हटाएं.
MainScene.xml
<?xml version="1.0" encoding="utf-8" ?>
<component extends="Scene" initialFocus="myVideo" name="MainScene">
<script type="text/brightscript">
<![CDATA[
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
runIMASDKTask()
end function
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end function
sub handleIMASDKInitialized()
' Follow your manifest manipulator (VTP) documentation to register a user
' streaming session if needed.
end sub
sub handleIMASDKErrors(message as object)
print "------ IMA DAI SDK failed ------"
if message <> invalid and message.getData() <> invalid
print "IMA DAI SDK Error ";message.getData()
end if
end sub
]]>
</script>
<children>
<Video height="720" id="myVideo" visible="false" width="1280"/>
</children>
</component>
IMA स्ट्रीम प्लेयर बनाएं
इसके बाद, आपको IMA स्ट्रीम प्लेयर बनाने के लिए, अपने मौजूदा roVideoScreen
का इस्तेमाल करना होगा.
लाइव स्ट्रीम पॉड सर्विंग
लाइव स्ट्रीम के लिए यह स्ट्रीम प्लेयर, कॉलबैक के तीन तरीके इस्तेमाल करता है:
streamInitialized
, adBreakStarted
, और adBreakEnded
.
साथ ही, स्ट्रीम लोड होने पर ट्रिक प्ले को बंद कर दें. यह उपयोगकर्ताओं को विज्ञापन के लिए ब्रेक शुरू होने वाले इवेंट के सक्रिय होने से पहले ही, शुरू होने वाले प्री-रोल को स्किप करने से रोकता है.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
</interface>
<script type="text/brightscript">
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
end sub
...
sub initializeIMASDK()
if m.ima = invalid
ima = New_IMASDK()
ima.initSdk()
m.ima = ima
end if
m.top.IMASDKInitialized = true
end sub
sub setupPlayerCallbacks()
m.player = m.ima.createPlayer()
m.player.top = m.top
m.player.streamInitialized = function(urlData)
m.top.videoNode.enableTrickPlay = false
m.top.urlData = urlData
end function
m.player.adBreakStarted = function(adBreakInfo)
print "------ Ad break started ------"
m.top.adPlaying = true
m.top.videoNode.enableTrickPlay = false
end function
m.player.adBreakEnded = function(adBreakInfo)
print "------ Ad break ended ------"
m.top.adPlaying = false
m.top.videoNode.enableTrickPlay = true
end function
end sub
</script>
...
</component>
वीओडी (वीडियो ऑन डिमांड) स्ट्रीम पॉड सर्विंग
वीओडी (वीडियो ऑन डिमांड) स्ट्रीम के लिए, स्ट्रीम प्लेयर में कॉलबैक के चार तरीके इस्तेमाल किए जाते हैं:
streamInitialized
, loadUrl
, adBreakStarted
, और adBreakEnded
. streamInitialized
कॉलबैक में, StreamManager.loadThirdPartyStream()
को कॉल करना न भूलें. ऐसा न करने पर, SDK टूल
loadUrl
फ़ंक्शन को ट्रिगर नहीं करेगा.
इस चरण में, अपने वीडियो टेक्नोलॉजी पार्टनर (वीटीपी) से स्ट्रीम के यूआरएल का अनुरोध भी किया जाता है. इसके लिए, आपको loadAdPodStream()
से मिला स्ट्रीम आईडी इस्तेमाल करना होता है. इसके बाद, विज्ञापनों के पॉड मेनिफ़ेस्ट और वीटीपी से मिले सबटाइटल के साथ
StreamManager.loadThirdPartyStream()
को कॉल करें.
साथ ही, स्ट्रीम लोड होने पर ट्रिक प्ले को बंद कर दें. यह उपयोगकर्ताओं को विज्ञापन के लिए ब्रेक शुरू होने वाले इवेंट के सक्रिय होने से पहले ही, शुरू होने वाले प्री-रोल को स्किप करने से रोकता है.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="adStitchedStreamInfo" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
<field id="streamParameters" type="assocarray" />
</interface>
<script type="text/brightscript">
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
end sub
...
sub initializeIMASDK()
if m.ima = invalid
ima = New_IMASDK()
ima.initSdk()
m.ima = ima
end if
m.top.IMASDKInitialized = true
end sub
sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
end sub
sub setupPlayerCallbacks()
m.player = m.ima.createPlayer()
m.player.top = m.top
m.player.streamInitialized = function(urlData)
adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
end function
m.player.loadUrl = function(streamInfo)
m.top.adStitchedStreamInfo = streamInfo
end function
m.player.adBreakStarted = function(adBreakInfo)
print "------ Ad break started ------"
m.top.adPlaying = true
m.top.videoNode.enableTrickPlay = false
end function
m.player.adBreakEnded = function(adBreakInfo)
print "------ Ad break ended ------"
m.top.adPlaying = false
m.top.videoNode.enableTrickPlay = true
end function
end sub
</script>
...
</component>
लाइव या वीओडी (वीडियो ऑन डिमांड) पॉडकास्ट दिखाने के लिए, स्ट्रीम का अनुरोध करें और उसे लागू करें
स्ट्रीम प्लेयर मिलने के बाद, स्ट्रीम का अनुरोध किया जा सकता है और उसे लागू किया जा सकता है.
इस उदाहरण में,
m.testPodServingStream
में सेव की गई पॉड सर्विंग स्ट्रीम का डेटा शामिल है.
लाइव स्ट्रीम पॉड सर्विंग
m.testPodServingStream
ऑब्जेक्ट में, वे पैरामीटर सेव करें जिनकी ज़रूरत Google Ad Manager को, विचाराधीन स्ट्रीम की पहचान करने के लिए होती है. जैसे, नेटवर्क कोड और कस्टम ऐसेट कुंजी. साथ ही, मेनिफ़ेस्ट यूआरएल को सेव करें, ताकि आपके मेनिफ़ेस्ट सर्वर को ऐक्सेस किया जा सके. इस मामले में, स्ट्रीम अनुरोध के दिखने के बाद, मेनिफ़ेस्ट यूआरएल में Google स्ट्रीम आईडी जोड़ा जाना चाहिए.
AdUI जैसे, adChoices आइकॉन के साथ काम करने के लिए, आपको उस नोड का रेफ़रंस भी देना होगा जिसमें आपका कॉन्टेंट वीडियो है.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testPodServingStream = {
title: "Test live stream for DAI Pod Serving",
assetKey: "test-live-stream",
networkCode: "your-network-code",
manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
apiKey: ""
}
runIMASDKTask()
end function
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
<field id="streamParameters" type="assocarray" />
</interface>
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
end sub
sub loadAdPodStream()
request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)
' Set the player object so that the request can trigger the player's
' callbacks at stream initialization or playback events.
request.player = m.player
' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
request.adUiNode = m.top.video
requestResult = m.ima.requestStream(request)
if requestResult <> invalid
print "Error requesting stream ";requestResult
return
end if
m.streamManager = invalid
while m.streamManager = invalid
sleep(50)
m.streamManager = m.ima.getStreamManager()
end while
if m.streamManager = invalid
errors = CreateObject("roArray", 1, True)
invalidStreamManagerError = "Invalid stream manager"
print invalidStreamManagerError
errors.push(invalidStreamManagerError)
m.top.errors = errors
return
end if
if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "Stream request returns an error. " ; m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
return
end if
setupStreamManager()
m.streamManager.start()
end sub
वीओडी (वीडियो ऑन डिमांड) स्ट्रीम पॉड सर्विंग
m.testPodServingStream
ऑब्जेक्ट में, स्ट्रीम के अनुरोध में इस्तेमाल किए गए नेटवर्क कोड को सेव किया जाएगा, ताकि Google Ad Manager स्ट्रीम आईडी दे सके. साथ ही, मेनिफ़ेस्ट यूआरएल सेव करें, जिसका इस्तेमाल आपके मेनिफ़ेस्ट में बदलाव करने वाले सर्वर पर, उपयोगकर्ता के खास मेनिफ़ेस्ट को ऐक्सेस करने के लिए किया जाता है.
AdUI जैसे विज्ञापन के आइकॉन के साथ काम करने के लिए, आपको उस नोड का रेफ़रंस भी पास करना होगा जिसमें आपका कॉन्टेंट वीडियो है.
MainScene.xml
sub init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testPodServingStream = {
title: "Pod Serving VOD Stream",
networkCode: "your-network-code",
VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
subtitleConfig: []
}
runIMASDKTask()
end sub
sub runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
end sub
sub loadAdPodStream()
request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)
' Set the player object so that the request can trigger the player
' callbacks at stream initialization or playback events.
request.player = m.player
' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
request.adUiNode = m.top.video
requestResult = m.ima.requestStream(request)
if requestResult <> invalid
print "Error requesting stream ";requestResult
return
end if
m.streamManager = invalid
while m.streamManager = invalid
sleep(50)
m.streamManager = m.ima.getStreamManager()
end while
if m.streamManager = invalid
errors = CreateObject("roArray", 1, True)
invalidStreamManagerError = "Invalid stream manager"
print invalidStreamManagerError
errors.push(invalidStreamManagerError)
m.top.errors = errors
return
end if
if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "Stream request returns an error. " ; m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
return
end if
setupStreamManager()
m.streamManager.start()
end sub
इवेंट लिसनर जोड़ें और स्ट्रीम शुरू करें
लाइव स्ट्रीम पॉड सर्विंग
अपनी स्ट्रीम का अनुरोध करने के बाद, बस कुछ ही काम बचे हैं: विज्ञापन की प्रोग्रेस को ट्रैक करने और Roku मैसेज को SDK टूल पर फ़ॉरवर्ड करने के लिए, इवेंट लिसनर जोड़ें. विज्ञापन सही तरीके से चलाने के लिए, यह ज़रूरी है कि आप सभी मैसेज SDK टूल पर फ़ॉरवर्ड करें. ऐसा न करने पर, विज्ञापन व्यू की गलत रिपोर्ट दी जा सकती है.
इस चरण में, [[STREAMID]]
मैक्रो को स्ट्रीम आईडी से बदलने के लिए एक फ़ंक्शन भी जोड़ा जाता है.
साथ ही, पूरे हो चुके मेनिफ़ेस्ट अनुरोध के यूआरएल को वीडियो प्लेयर में भी भेजा जाता है.
इस चरण में लागू करने को स्ट्रीम आईडी मिलता है. हालांकि, आपके वीटीपी इंटिग्रेशन के आधार पर, हो सकता है कि यह इस चरण से पहले उपलब्ध हो.
MainScene.xml
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")
m.sdkTask.control = "RUN"
end function
sub loadAdStitchedStream(message as object)
print "Ad pod stream information ";message
adPodStreamInfo = message.getData()
manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
playStream(manifest, adPodStreamInfo.format)
end sub
sub playStream(url as string, format as string)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.testPodservingStream.title
vidContent.streamformat = format
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
if m.streamManager <> invalid
runLoop()
end if
end sub
sub runLoop()
m.top.videoNode.timedMetaDataSelectionKeys = ["*"]
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
m.port = CreateObject("roMessagePort")
m.top.videoNode.observeField("position", m.port)
m.top.videoNode.observeField("timedMetaData", m.port)
m.top.videoNode.observeField("timedMetaData2", m.port)
m.top.videoNode.observeField("state", m.port)
while True
msg = wait(1000, m.port)
if m.top.videoNode = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.videoNode.position
if currentTime > 3 And not m.top.adPlaying
m.top.videoNode.enableTrickPlay = true
end if
end while
end sub
sub setupStreamManager()
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub
sub startCallback(ad as object)
print "Callback from SDK -- Start called - "
end sub
sub firstQuartileCallback(ad as object)
print "Callback from SDK -- First quartile called - "
end sub
sub midpointCallback(ad as object)
print "Callback from SDK -- Midpoint called - "
end sub
sub thirdQuartileCallback(ad as object)
print "Callback from SDK -- Third quartile called - "
end sub
sub completeCallback(ad as object)
print "Callback from SDK -- Complete called - "
end sub
function errorCallback(error as object)
print "Callback from SDK -- Error called - " ; error
m.errorState = True
end function
वीओडी (वीडियो ऑन डिमांड) स्ट्रीम पॉड सर्विंग
अपनी स्ट्रीम का अनुरोध करने के बाद, बस कुछ ही काम बचे हैं: विज्ञापन की प्रोग्रेस को ट्रैक करने और Roku मैसेज को SDK टूल पर फ़ॉरवर्ड करने के लिए, इवेंट लिसनर जोड़ें. विज्ञापन सही तरीके से चलाने के लिए, सभी मैसेज को SDK टूल पर फ़ॉरवर्ड करना ज़रूरी है. ऐसा न करने पर, विज्ञापन व्यू की गलत तरीके से रिपोर्ट की जा सकती है.
MainScene.xml
sub runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")
m.sdkTask.control = "RUN"
end sub
sub loadAdStitchedStream(message as object)
print "Ad pod stream information ";message
adPodStreamInfo = message.getData()
end sub
sub playStream(url as string, format as string, subtitleConfig as object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.title = m.testPodservingStream.title
vidContent.url = url
vidContent.subtitleConfig = subtitleConfig
vidContent.streamformat = format
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
if m.streamManager <> invalid
runLoop()
end if
end sub
sub runLoop()
m.top.videoNode.timedMetaDataSelectionKeys = ["*"]
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
m.port = CreateObject("roMessagePort")
m.top.videoNode.observeField("position", m.port)
m.top.videoNode.observeField("timedMetaData", m.port)
m.top.videoNode.observeField("timedMetaData2", m.port)
m.top.videoNode.observeField("state", m.port)
while True
msg = wait(1000, m.port)
if m.top.videoNode = invalid
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.videoNode.position
if currentTime > 3 and not m.top.adPlaying
m.top.videoNode.enableTrickPlay = true
end if
end while
end sub
sub setupStreamManager()
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub
sub startCallback(ad as object)
print "Callback from SDK -- Start called - "
end sub
sub firstQuartileCallback(ad as object)
print "Callback from SDK -- First quartile called - "
end sub
sub midpointCallback(ad as object)
print "Callback from SDK -- Midpoint called - "
end sub
sub thirdQuartileCallback(ad as object)
print "Callback from SDK -- Third quartile called - "
end sub
sub completeCallback(ad as object)
print "Callback from SDK -- Complete called - "
end sub
sub errorCallback(error as object)
print "Callback from SDK -- Error called - " ; error
m.errorState = True
end sub