เริ่มต้นใช้งาน IMA DAI SDK

IMA SDK ช่วยให้ผสานรวมโฆษณามัลติมีเดียลงในเว็บไซต์และแอปได้อย่างง่ายดาย IMA SDK สามารถส่งคําขอโฆษณาจากเซิร์ฟเวอร์โฆษณา ที่เป็นไปตามข้อกําหนดของ VAST ใดก็ได้ และจัดการการเล่นโฆษณาในแอป เมื่อใช้ IMA DAI SDK แอปจะส่งคําขอสตรีมสําหรับโฆษณาและวิดีโอเนื้อหา ไม่ว่าจะเป็น VOD หรือเนื้อหาสด จากนั้น SDK จะแสดงผลสตรีมวิดีโอแบบรวม คุณจึงไม่ต้องจัดการการสลับระหว่างโฆษณากับวิดีโอเนื้อหาภายในแอป

เลือกโซลูชัน DAI ที่คุณสนใจ

บริการแบบเต็มรูปแบบ การแสดงพ็อด

คู่มือนี้สาธิตวิธีเล่นสตรีมแบบสดหรือ VOD ที่ให้บริการพ็อด DAI โดยใช้ IMA DAI SDK สําหรับ Roku หากต้องการดูหรือทําตามการผสานรวมตัวอย่างที่เสร็จสมบูรณ์ ให้ดาวน์โหลดตัวอย่างการแสดงพ็อด

หมายเหตุ: IMA DAI SDK สําหรับ Roku รองรับทั้งสตรีม HLS และ DASH โดยไม่มีความแตกต่างในการใช้งาน

หากต้องการใช้ IMA DAI คุณต้องมีบัญชี Ad Manager 360 Advanced หากมีบัญชี Ad Manager โปรดติดต่อผู้จัดการฝ่ายดูแลลูกค้าเพื่อขอรายละเอียดเพิ่มเติม ดูข้อมูลเกี่ยวกับการลงชื่อสมัครใช้ Ad Manager ได้ที่ศูนย์ช่วยเหลือของ Ad Manager

หมายเหตุ: ดูข้อมูลเกี่ยวกับการผสานรวมกับแพลตฟอร์มอื่นๆ หรือการใช้ SDK ฝั่งไคลเอ็นต์ IMA ได้ที่ SDK โฆษณาสื่ออินเทอร์แอกทีฟ

ภาพรวมของ IMA DAI Pod Serving

การใช้ Pod Serving โดยใช้ IMA DAI ประกอบด้วยคอมโพเนนต์ SDK หลัก 2 รายการดังที่แสดงในคู่มือนี้

• StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest(): สร้างออบเจ็กต์ที่กําหนดคําขอสตรีมไปยังเซิร์ฟเวอร์โฆษณาของ Google คำขอเหล่านี้จะระบุรหัสเครือข่าย และ Pod Liveima.StreamRequest ยังต้องใช้คีย์เนื้อหาที่กำหนดเองและคีย์ API (ไม่บังคับ) ด้วย
• StreamManager: ออบเจ็กต์ที่จัดการการสื่อสารระหว่างสตรีมวิดีโอกับ IMA DAI SDK เช่น การส่งคําสั่ง Ping ติดตามและส่งต่อเหตุการณ์สตรีมไปยังผู้เผยแพร่โฆษณา

นอกจากนี้ คุณจะต้องส่งคําขอไปยังเซิร์ฟเวอร์การจัดการไฟล์ Manifest เพื่อดึงข้อมูลไฟล์ Manifest ของสตรีมเพื่อให้แอปแสดง กระบวนการที่แน่ชัดอาจแตกต่างกันไปตามพาร์ทเนอร์เทคโนโลยีวิดีโอ (VTP)

สำคัญ: คู่มือนี้จะถือว่าเซิร์ฟเวอร์การจัดการไฟล์ Manifest คาดหวังว่าจะได้รับคําขอ GET ที่มีรหัสสตรีมซึ่งส่งผ่านเป็นตัวแปรการค้นหา ใช้มาโคร [[STREAMID]] เป็นตัวยึดตําแหน่งใน URL คำขอ แล้วแทนที่ด้วยรหัสสตรีมก่อนส่งคำขอ เซิร์ฟเวอร์การจัดการไฟล์ Manifest อาจแตกต่างออกไป

ข้อกำหนดเบื้องต้น

• อ่านหน้าความเข้ากันได้เพื่อให้แน่ใจว่าระบบรองรับกรณีการใช้งานที่ต้องการ
• ดาวน์โหลดโค้ดตัวอย่างโปรแกรมเล่นของ Roku
• ติดตั้งใช้งานโค้ดเพลเยอร์ตัวอย่างในอุปกรณ์ Roku เพื่อยืนยันว่าการตั้งค่าการพัฒนาทํางาน

เล่นวิดีโอ

วิดีโอตัวอย่าง เพลเยอร์ที่ให้มาจะเล่นวิดีโอเนื้อหาได้ทันที ติดตั้งใช้งานโปรแกรมเล่นตัวอย่างในอุปกรณ์ Roku เพื่อให้แน่ใจว่าสภาพแวดล้อมการพัฒนาซอฟต์แวร์ได้รับการตั้งค่าอย่างถูกต้อง

เปลี่ยนวิดีโอเพลเยอร์ของคุณให้เป็นโปรแกรมเล่นสตรีม IMA DAI

ทำตามขั้นตอนเหล่านี้เพื่อติดตั้งใช้งานโปรแกรมเล่นสตรีม

สร้าง Sdk.xml

เพิ่มไฟล์ใหม่ลงในโปรเจ็กต์ข้าง MainScene.xml ชื่อ Sdk.xml และใส่ข้อมูลเริ่มต้นต่อไปนี้

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

คุณต้องแก้ไขทั้ง 2 ไฟล์นี้ (MainScene.xml และ Sdk.xml) ตลอดทั้งคู่มือนี้

โหลดเฟรมเวิร์ก IMA DAI SDK

หากต้องการโหลดเฟรมเวิร์ก ให้เพิ่มข้อมูลต่อไปนี้ลงใน manifest และ Sdk.xml

manifest

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

เริ่มต้น IMA DAI SDK

ขั้นตอนแรกในการโหลดสตรีมการแทรกโฆษณาแบบไดนามิกของ IMA คือโหลดและเริ่มต้น IMA DAI SDK บรรทัดต่อไปนี้จะเริ่มต้นสคริปต์ IMA DAI SDK

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

ตอนนี้ให้เริ่มงานนี้ใน MainScene.xml และนําการเรียกให้โหลดสตรีมเนื้อหาออก

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

สร้างโปรแกรมเล่นสตรีม IMA

ถัดไป คุณต้องใช้ roVideoScreen ที่มีอยู่เพื่อสร้างโปรแกรมเล่นสตรีม IMA

การแสดงพ็อดสตรีมแบบสด

สตรีมเพลเยอร์นี้ใช้เมธอดการเรียกกลับ 3 รายการสำหรับสตรีมแบบสด ได้แก่ streamInitialized, adBreakStarted และ adBreakEnded

และปิดใช้การเล่นกลโกงเมื่อโหลดสตรีม ซึ่งจะช่วยป้องกันไม่ให้ผู้ใช้ข้ามโฆษณาก่อนเข้าเนื้อหาทันทีที่โฆษณาเริ่มเล่น ก่อนที่เหตุการณ์ช่วงพักโฆษณาจะเริ่มขึ้น

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

การแสดงพ็อดสตรีม VOD

สตรีมเพลเยอร์นี้ใช้เมธอดการเรียกกลับ 4 รายการสำหรับสตรีม VOD ได้แก่ streamInitialized, loadUrl, adBreakStarted และ adBreakEnded ในสายกลับของ streamInitialized โปรดโทรหา StreamManager.loadThirdPartyStream() หากไม่ดำเนินการดังกล่าว SDK จะไม่ทริกเกอร์ฟังก์ชัน loadUrl

ในขั้นตอนนี้ คุณยังขอ URL สตรีมจากพาร์ทเนอร์เทคโนโลยีวิดีโอ (VTP) ด้วยโดยใช้รหัสสตรีมที่ได้จากloadAdPodStream() จากนั้นเรียกใช้ StreamManager.loadThirdPartyStream() ด้วยไฟล์ Manifest ของพ็อดโฆษณาและคำบรรยายแทนเสียงที่ VTP แสดง

และปิดใช้การเล่นกลโกงเมื่อโหลดสตรีม ซึ่งจะช่วยป้องกันไม่ให้ผู้ใช้ข้ามโฆษณาก่อนเข้าเนื้อหาทันทีที่โฆษณาเริ่มเล่น ก่อนที่เหตุการณ์ช่วงพักโฆษณาจะเริ่มขึ้น

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

สร้างและดำเนินการตามคำขอสตรีมที่ให้บริการพ็อดแบบสดหรือ VOD

หลังจากมีโปรแกรมเล่นสตรีมแล้ว คุณสามารถสร้างและดำเนินการตามคำขอสตรีมได้ ตัวอย่างนี้มีข้อมูลสตรีมการแสดงพ็อดที่เก็บไว้ใน m.testPodServingStream

การแสดงพ็อดสตรีมแบบสด

ในออบเจ็กต์ m.testPodServingStream ให้จัดเก็บพารามิเตอร์ที่ Google Ad Manager ต้องใช้เพื่อระบุสตรีมที่เป็นปัญหา เช่น รหัสเครือข่ายและคีย์ชิ้นงานที่กำหนดเอง รวมถึงจัดเก็บ URL ของไฟล์ Manifest ที่ใช้ในการเข้าถึงเซิร์ฟเวอร์การจัดการไฟล์ Manifest ในกรณีนี้ URL ของไฟล์ Manifest จะต้องเพิ่มรหัสสตรีมของ Google หลังจากที่ระบบแสดงผลคำขอสตรีมแล้ว

หากต้องการรองรับ AdUI เช่น ไอคอนตัวเลือกโฆษณาอื่นๆ คุณต้องส่งการอ้างอิงไปยังโหนดที่มีวิดีโอเนื้อหาเป็นส่วนหนึ่งของคำขอด้วย

หมายเหตุ: พารามิเตอร์สตรีมที่ระบุไว้ใช้สําหรับสตรีมพ็อดแบบสด หากต้องการทดสอบด้วยสตรีมพอด VOD คุณจะต้องระบุพารามิเตอร์สตรีมทดสอบของคุณเอง

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

การแสดงพ็อดสตรีม VOD

ในออบเจ็กต์ m.testPodServingStream คุณจะจัดเก็บรหัสเครือข่ายที่ใช้ในคำขอสตรีมเพื่อให้ Google Ad Manager ระบุรหัสสตรีมได้ นอกจากนี้ ให้จัดเก็บ URL ของไฟล์ Manifest ที่ใช้เข้าถึงไฟล์ Manifest ของผู้ใช้ที่เฉพาะเจาะจงในเซิร์ฟเวอร์การจัดการไฟล์ Manifest ด้วย

หากต้องการรองรับ AdUI เช่น ไอคอนตัวเลือกโฆษณาอื่นๆ คุณต้องส่งการอ้างอิงไปยังโหนดที่มีวิดีโอเนื้อหาเป็นส่วนหนึ่งของคำขอด้วย

หมายเหตุ: คุณจะต้องระบุโค้ดเครือข่ายและ URL ของไฟล์ Manifest ของคุณเองเพื่อทดสอบการใช้งานสตรีม VOD

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

เพิ่ม Listener เหตุการณ์และเริ่มสตรีม

การแสดงพ็อดสตรีมแบบสด

หลังจากขอสตรีมแล้ว คุณต้องทำเพียงไม่กี่อย่างเท่านั้น ได้แก่ เพิ่มโปรแกรมรับฟังเหตุการณ์เพื่อติดตามความคืบหน้าของโฆษณาและส่งต่อข้อความ Roku ไปยัง SDK คุณต้องส่งต่อข้อความทั้งหมดไปยัง SDK เพื่อให้เล่นโฆษณาได้อย่างถูกต้อง มิเช่นนั้นระบบจะรายงานยอดดูโฆษณาอย่างไม่ถูกต้อง

ในขั้นตอนนี้ คุณยังเพิ่มฟังก์ชันเพื่อแทนที่มาโคร [[STREAMID]] ด้วยรหัสสตรีม และส่ง URL คำขอไฟล์ Manifest ที่เสร็จสมบูรณ์ไปยังโปรแกรมเล่นวิดีโอด้วย การติดตั้งใช้งานนี้จะรับรหัสสตรีมในขั้นตอนนี้ แต่อาจใช้งานได้ก่อนขั้นตอนนี้ ทั้งนี้ขึ้นอยู่กับการผสานรวม VTP

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

การแสดงพ็อดสตรีม VOD

หลังจากขอสตรีมแล้ว คุณต้องทำเพียงไม่กี่อย่างเท่านั้น ได้แก่ เพิ่มโปรแกรมรับฟังเหตุการณ์เพื่อติดตามความคืบหน้าของโฆษณาและส่งต่อข้อความ Roku ไปยัง SDK คุณจำเป็นต้องส่งต่อข้อความทั้งหมดไปยัง SDK เพื่อให้การเล่นโฆษณาถูกต้อง มิเช่นนั้น ระบบจะรายงานยอดดูโฆษณาอย่างไม่ถูกต้อง

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub