IMA DAI SDK 시작하기

IMA SDK를 사용하면 멀티미디어 광고를 웹사이트와 앱에 쉽게 통합할 수 있습니다. IMA SDK는 원하는 형식에서 광고를 <ph type="x-smartling-placeholder"></ph> VAST 호환 광고 서버를 사용하고 앱에서 광고 재생을 관리할 수 있습니다. IMA DAI SDK를 사용하면 앱에서 광고 및 콘텐츠 동영상(VOD 또는 라이브 콘텐츠)에 대한 스트림 요청 그러면 SDK는 광고와 콘텐츠 동영상 간의 전환을 관리할 필요가 없음 표시할 수 있습니다.

관심 있는 DAI 솔루션 선택

<ph type="x-smartling-placeholder"></ph> 전체 서비스 광고 모음 게재

이 가이드에서는 다음을 사용하여 라이브 또는 VOD 스트림을 게재하는 DAI 광고 모음을 재생하는 방법을 보여줍니다. 있습니다.

참고: Roku용 IMA DAI SDK는 구현 차이 없이 HLS 및 DASH 스트림 모두 지원합니다.

IMA DAI를 사용하려면 Ad Manager 360 고급 계정 만약 Ad Manager 계정이 있는 경우 자세한 내용은 계정 관리자에게 문의하세요. 정보 자세한 내용은 Ad Manager 고객센터를 참고하세요.

참고: 다른 플랫폼과의 통합 또는 자세한 내용은 <ph type="x-smartling-placeholder"></ph> 양방향 미디어 광고 SDK를 참고하세요.

IMA DAI 광고 모음 게재 개요

IMA DAI를 사용하여 광고 모음 게재를 구현하려면 두 가지 주요 SDK 구성요소인 자세한 내용은 이 가이드에 나와 있습니다.

• StreamRequest.createPodLiveStreamRequest() 드림 / StreamRequest.createPodVodStreamRequest(): Google 광고에 대한 스트림 요청을 정의하는 객체를 만듭니다. 있습니다 이러한 요청은 네트워크 코드 및 포드 라이브를 지정합니다. ima.StreamRequest에는 맞춤 애셋 키와 선택적 매개변수도 필요합니다. API 키.
• StreamManager: 동영상 스트림과 IMA DAI SDK 간의 통신을 처리하는 개체입니다. 예를 들어 추적 핑을 실행하고 스트림 이벤트를 있습니다.

또한 매니페스트 조작을 위한 요청을 해야 함 서버를 호출하여 스트림을 검색합니다. 매니페스트를 만들어야 합니다. 정확한 프로세스는 동영상 기술에 따라 다를 수 있습니다. 파트너 (VTP)를 VTP로 전송합니다.

중요: 이 가이드에서는 매니페스트 조작이 서버는 쿼리 변수로 전달된 스트림 ID가 포함된 GET 요청을 예상합니다. 사용 [[STREAMID]] 매크로를 요청 URL에 자리표시자로 사용하고 스트림 ID와 SNS를 미리 보는 것입니다. 매니페스트 조작 서버 다를 수 있습니다.

기본 요건

• Google의 호환성 검토 페이지를 검토하여 지원되는 사용 사례일 수 있습니다
• Roku 샘플 플레이어 다운로드 코드를 찾습니다.
• Roku 기기에 샘플 플레이어 코드를 배포하여 확인할 수 있습니다

동영상 재생

샘플 동영상 플레이어 콘텐츠 동영상을 바로 재생합니다. 샘플 플레이어를 Roku 기기에서 개발 환경이 제대로 설정되었는지 확인하세요.

동영상 플레이어를 IMA DAI 스트림 플레이어로 전환

스트림 플레이어를 구현하려면 다음 단계를 따르세요.

Sdk.xml 만들기

프로젝트에 Sdk.xml이라는 새 파일을 MainScene.xml과 함께 추가합니다. 다음 상용구를 추가합니다.

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

파일 전체에서 MainScene.xml 및 Sdk.xml 파일을 모두 수정해야 합니다. 이 가이드를 참고하세요.

IMA DAI SDK 프레임워크 로드

프레임워크를 로드하려면 manifest 및 Sdk.xml에 다음을 추가합니다.

매니페스트

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

IMA DAI SDK 초기화

IMA 동적 광고 삽입 스트림을 로드하는 첫 번째 단계는 초기화해야 합니다 다음은 IMA DAI SDK 스크립트를 초기화합니다.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

이제 MainScene.xml에서 이 작업을 시작하고 콘텐츠를 로드하는 호출을 삭제합니다. 있습니다.

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

IMA 스트림 플레이어 만들기

다음으로 기존 roVideoScreen를 사용하여 IMA 스트림을 만들어야 합니다. 있습니다.

라이브 스트림 광고 모음 게재

이 스트림 플레이어는 라이브 스트림의 경우 세 가지 콜백 메서드를 구현합니다. streamInitialized, adBreakStarted, adBreakEnded

스트림이 로드될 때 트릭 플레이를 사용 중지합니다. 이렇게 하면 사용자가 프리롤이 시작되는 순간, 광고 시간이 시작되기 전에 프리롤 건너뛰기 이벤트가 시작됩니다.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

VOD 스트림 광고 모음 게재

이 스트림 플레이어는 VOD 스트림의 경우 4가지 콜백 메서드를 구현합니다. streamInitialized, loadUrl, adBreakStarted, adBreakEnded streamInitialized 콜백이 필요합니다. StreamManager.loadThirdPartyStream() 그렇지 않으면 SDK가 생성됩니다. loadUrl 함수를 트리거하지 않음

이 단계에서는 동영상 기술 파트너에게 스트림 URL도 요청합니다. (VTP)를 loadAdPodStream()에서 가져온 스트림 ID로 바꿉니다. 그런 다음 StreamManager.loadThirdPartyStream()를 광고 모음 매니페스트 및 자막이 표시됩니다.

스트림이 로드될 때 트릭 플레이를 사용 중지합니다. 이렇게 하면 사용자가 프리롤이 시작되는 순간, 광고 시간이 시작되기 전에 프리롤 건너뛰기 이벤트가 시작됩니다.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

실시간 또는 VOD 광고 모음 게재 스트림 요청을 만들고 실행합니다.

스트림 플레이어가 있으면 스트림 요청을 만들고 실행할 수 있습니다. 이 예시에는 m.testPodServingStream

라이브 스트림 광고 모음 게재

m.testPodServingStream 객체에 Google Ads 시스템이 관리자는 문제가 되는 스트림(예: 네트워크 코드 및 맞춤 애셋 키입니다. 매니페스트에 액세스하는 데 사용되는 매니페스트 URL도 저장 전송합니다. 이 경우 매니페스트 URL에 스트림 요청이 반환된 후 추가된 스트림 ID입니다.

adChoices 아이콘과 같은 AdUI를 지원하려면 콘텐츠 동영상이 포함된 노드에 대한 참조가 포함됩니다.

참고: 제공된 스트림 매개변수는 라이브 광고 모음 스트림용입니다. VOD로 테스트하기 포드 스트림에 자체 테스트 스트림 매개변수를 제공해야 합니다.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

VOD 스트림 광고 모음 게재

m.testPodServingStream 객체에 사용된 네트워크 코드를 Google Ad Manager가 스트림 ID를 제공할 수 있습니다. 추가 매장 매니페스트의 사용자별 매니페스트에 액세스하는 데 사용되는 매니페스트 URL 전송합니다.

adChoices 아이콘과 같은 AdUI를 지원하려면 노드로 만들 수 있습니다.

참고: 테스트하려면 자체 네트워크 코드와 매니페스트 URL을 제공해야 합니다. VOD 스트림 구현

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

이벤트 리스너 추가 및 스트림 시작

라이브 스트림 광고 모음 게재

스트림을 요청한 후 할 일은 이벤트 리스너를 사용하여 광고 진행률을 추적하고 Roku 메시지를 SDK로 전달합니다. 올바른 광고가 게재될 수 있도록 모든 메시지를 SDK에 전달하는 것이 중요합니다. 있습니다. 그렇지 않으면 광고 조회수가 잘못 보고됩니다.

이 단계에서는 [[STREAMID]] 매크로를 다음으로 대체하는 함수도 추가합니다. 동영상 플레이어에 완성된 매니페스트 요청 URL을 전달할 수 있습니다. 이 구현은 이 단계에서 스트림 ID를 가져오지만 VTP에 따라 다릅니다. 이 단계 전에 사용할 수 있습니다.

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

VOD 스트림 광고 모음 게재

스트림을 요청한 후 할 일은 이벤트 리스너를 사용하여 광고 진행률을 추적하고 Roku 메시지를 SDK로 전달합니다. 그것은 모든 메시지를 SDK에 전달하여 올바른 광고가 있습니다. 그렇지 않으면 광고 조회수가 잘못 보고될 수 있습니다.

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub