IMA DAI SDK দিয়ে শুরু করুন

IMA SDKগুলি আপনার ওয়েবসাইট এবং অ্যাপগুলিতে মাল্টিমিডিয়া বিজ্ঞাপনগুলিকে একীভূত করা সহজ করে তোলে৷ IMA SDK যেকোন VAST-সঙ্গী বিজ্ঞাপন সার্ভার থেকে বিজ্ঞাপনের অনুরোধ করতে পারে এবং আপনার অ্যাপে বিজ্ঞাপন প্লেব্যাক পরিচালনা করতে পারে। IMA DAI SDK-এর সাথে, অ্যাপগুলি বিজ্ঞাপন এবং বিষয়বস্তু ভিডিওর জন্য একটি স্ট্রিম অনুরোধ করে—হয় VOD বা লাইভ সামগ্রী। SDK তারপরে একটি সম্মিলিত ভিডিও স্ট্রিম ফেরত দেয়, যাতে আপনাকে আপনার অ্যাপের মধ্যে বিজ্ঞাপন এবং বিষয়বস্তু ভিডিওর মধ্যে স্যুইচিং পরিচালনা করতে হবে না।

আপনি আগ্রহী DAI সমাধান নির্বাচন করুন

সম্পূর্ণ পরিষেবা পড পরিবেশন

এই নির্দেশিকাটি দেখায় কিভাবে একটি DAI পড সার্ভিং লাইভ বা VOD স্ট্রিম খেলতে হয়, Roku এর জন্য IMA DAI SDK ব্যবহার করে।

দ্রষ্টব্য: Roku-এর জন্য IMA DAI SDK HLS এবং DASH উভয় স্ট্রীমকে সমর্থন করে, কোনো বাস্তবায়ন পার্থক্য নেই।

IMA DAI ব্যবহার করতে, আপনার একটি Ad Manager 360 Advanced অ্যাকাউন্ট থাকতে হবে। আপনার যদি অ্যাড ম্যানেজার অ্যাকাউন্ট থাকে, তাহলে আরও বিশদ বিবরণের জন্য আপনার অ্যাকাউন্ট পরিচালকের সাথে যোগাযোগ করুন। অ্যাড ম্যানেজারের জন্য সাইন আপ করার বিষয়ে তথ্যের জন্য, অ্যাড ম্যানেজার সহায়তা কেন্দ্রে যান।

দ্রষ্টব্য: অন্যান্য প্ল্যাটফর্মের সাথে একীভূতকরণ বা IMA ক্লায়েন্ট-সাইড SDK ব্যবহার করার বিষয়ে তথ্যের জন্য, ইন্টারেক্টিভ মিডিয়া বিজ্ঞাপন SDK দেখুন।

IMA DAI পড সার্ভিং ওভারভিউ

IMA DAI ব্যবহার করে পড পরিবেশন বাস্তবায়নে দুটি প্রধান SDK উপাদান জড়িত, যা এই নির্দেশিকায় প্রদর্শিত হয়েছে:

• StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest() : এমন একটি বস্তু তৈরি করে যা Google-এর বিজ্ঞাপন সার্ভারে একটি স্ট্রিম অনুরোধ সংজ্ঞায়িত করে। এই অনুরোধগুলি একটি নেটওয়ার্ক কোড নির্দিষ্ট করে, এবং পড লাইভ ima.StreamRequest স্ট্রিমরিকোয়েস্টের জন্য একটি কাস্টম সম্পদ কী এবং একটি ঐচ্ছিক API কী প্রয়োজন।
• StreamManager : একটি বস্তু যা ভিডিও স্ট্রীম এবং IMA DAI SDK-এর মধ্যে যোগাযোগ পরিচালনা করে, যেমন ফায়ারিং ট্র্যাকিং পিং এবং প্রকাশকের কাছে স্ট্রিম ইভেন্ট ফরওয়ার্ড করা।

এছাড়াও, আপনার অ্যাপটি প্রদর্শনের জন্য স্ট্রিম ম্যানিফেস্ট পুনরুদ্ধার করতে আপনাকে আপনার ম্যানিফেস্ট ম্যানিপুলেশন সার্ভারে একটি অনুরোধ করতে হবে। সঠিক প্রক্রিয়া ভিডিও প্রযুক্তি অংশীদার (VTP) থেকে VTP-তে পরিবর্তিত হতে পারে।

গুরুত্বপূর্ণ: এই নির্দেশিকাটির উদ্দেশ্যে, ধরে নিন যে ম্যানিফেস্ট ম্যানিপুলেশন সার্ভার একটি জিইটি অনুরোধ আশা করে যেটি স্ট্রিম আইডি একটি কোয়েরি ভেরিয়েবল হিসাবে পাস করা হয়েছে৷ অনুরোধ URL-এ একটি স্থানধারক হিসাবে ম্যাক্রো [[STREAMID]] ব্যবহার করুন এবং অনুরোধ করার আগে এটিকে স্ট্রিম আইডি দিয়ে প্রতিস্থাপন করুন। আপনার ম্যানিফেস্ট ম্যানিপুলেশন সার্ভার ভিন্ন হতে পারে।

পূর্বশর্ত

• আপনার উদ্দেশ্য ব্যবহার কেস সমর্থিত তা নিশ্চিত করতে আমাদের সামঞ্জস্য পৃষ্ঠাটি পড়ুন।
• আমাদের Roku নমুনা প্লেয়ার কোড ডাউনলোড করুন.
• আপনার ডেভেলপমেন্ট সেট আপ কাজ করছে কিনা তা যাচাই করতে একটি Roku ডিভাইসে নমুনা প্লেয়ার কোড স্থাপন করুন।

আপনার ভিডিও চালান

প্রদত্ত নমুনা ভিডিও প্লেয়ার বাক্সের বাইরে একটি বিষয়বস্তু ভিডিও চালায়। আপনার ডেভেলপমেন্ট এনভায়রনমেন্ট সঠিকভাবে সেট আপ করা হয়েছে তা নিশ্চিত করতে আপনার Roku ডিভাইসে নমুনা প্লেয়ার স্থাপন করুন।

আপনার ভিডিও প্লেয়ারটিকে একটি IMA DAI স্ট্রিম প্লেয়ারে পরিণত করুন৷

একটি স্ট্রিম প্লেয়ার বাস্তবায়ন করতে এই পদক্ষেপগুলি অনুসরণ করুন৷

Sdk.xml তৈরি করুন

MainScene.xml এর সাথে Sdk.xml নামে একটি নতুন ফাইল যোগ করুন এবং নিম্নলিখিত বয়লারপ্লেট যোগ করুন:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

এই নির্দেশিকা জুড়ে আপনাকে এই উভয় ফাইল ( MainScene.xml এবং Sdk.xml ) সম্পাদনা করতে হবে।

IMA DAI SDK ফ্রেমওয়ার্ক লোড করুন

ফ্রেমওয়ার্ক লোড করতে, manifest এবং Sdk.xml নিম্নলিখিত যোগ করুন:

প্রকাশ

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

IMA DAI SDK শুরু করুন৷

আপনার IMA ডায়নামিক অ্যাড সন্নিবেশ স্ট্রীম লোড করার প্রথম ধাপ হল IMA DAI SDK লোড করা এবং আরম্ভ করা। নিম্নলিখিতটি IMA DAI SDK স্ক্রিপ্ট শুরু করে।

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

এখন MainScene.xml এ এই কাজটি শুরু করুন এবং কন্টেন্ট স্ট্রিম লোড করার জন্য কলটি সরিয়ে দিন।

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA DAI SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA DAI SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

একটি IMA স্ট্রিম প্লেয়ার তৈরি করুন

এর পরে, একটি IMA স্ট্রিম প্লেয়ার তৈরি করতে আপনাকে আপনার বিদ্যমান roVideoScreen ব্যবহার করতে হবে।

লাইভ স্ট্রিম পড পরিবেশন

লাইভ স্ট্রীমের জন্য, এই স্ট্রিম প্লেয়ার তিনটি কলব্যাক পদ্ধতি প্রয়োগ করে: streamInitialized , adBreakStarted এবং adBreakEnded ।

স্ট্রীম লোড হলে ট্রিক প্লে অক্ষম করুন। এটি ব্যবহারকারীদের বিজ্ঞাপন বিরতি শুরু হওয়ার ইভেন্টটি বরখাস্ত হওয়ার আগে এটি শুরু হওয়ার সাথে সাথে একটি প্রি-রোল এড়িয়ে যেতে বাধা দেয়৷

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

ভিওডি স্ট্রিম পড পরিবেশন

VOD স্ট্রিমগুলির জন্য, এই স্ট্রিম প্লেয়ারটি চারটি কলব্যাক পদ্ধতি প্রয়োগ করে: streamInitialized , loadUrl , adBreakStarted , এবং adBreakEnded ৷ স্ট্রীম streamInitialized কলব্যাকে, StreamManager.loadThirdPartyStream() কল করতে ভুলবেন না। এটি করতে ব্যর্থ হলে SDK loadUrl ফাংশন ট্রিগার করবে না।

এই ধাপে, আপনি loadAdPodStream() এ প্রাপ্ত একটি স্ট্রীম আইডি সহ আপনার ভিডিও প্রযুক্তি অংশীদার (VTP) থেকে একটি স্ট্রিম URL এর জন্য অনুরোধ করবেন৷ তারপর, বিজ্ঞাপন পড ম্যানিফেস্ট এবং আপনার VTP দ্বারা ফিরে আসা যেকোনো সাবটাইটেল সহ StreamManager.loadThirdPartyStream() এ কল করুন।

স্ট্রীম লোড হলে ট্রিক প্লে অক্ষম করুন। এটি ব্যবহারকারীদের বিজ্ঞাপন বিরতি শুরু হওয়ার ইভেন্টটি বরখাস্ত হওয়ার আগে এটি শুরু হওয়ার সাথে সাথে একটি প্রি-রোল এড়িয়ে যেতে বাধা দেয়৷

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

একটি লাইভ বা VOD পড সার্ভিং স্ট্রিম অনুরোধ তৈরি করুন এবং চালান

আপনার কাছে একটি স্ট্রিম প্লেয়ার থাকার পরে, আপনি একটি স্ট্রিম অনুরোধ তৈরি এবং কার্যকর করতে পারেন৷ এই উদাহরণে m.testPodServingStream এ সঞ্চিত একটি পড সার্ভিং স্ট্রিমের ডেটা রয়েছে।

লাইভ স্ট্রিম পড পরিবেশন

m.testPodServingStream অবজেক্টে, একটি নেটওয়ার্ক কোড এবং কাস্টম অ্যাসেট কী-এর মতো প্রশ্নে থাকা স্ট্রীম শনাক্ত করার জন্য Google Ad Manager-এর প্রয়োজনীয় প্যারামিটারগুলি সঞ্চয় করুন৷ এছাড়াও আপনার ম্যানিফেস্ট ম্যানিপুলেশন সার্ভার অ্যাক্সেস করতে ব্যবহৃত ম্যানিফেস্ট URL সংরক্ষণ করুন। এই ক্ষেত্রে, স্ট্রিম অনুরোধ ফেরত দেওয়ার পরে ম্যানিফেস্ট URL-এ Google স্ট্রিম আইডি যোগ করা প্রয়োজন।

AdUI সমর্থন করতে সক্ষম হতে, যেমন adChoices আইকন, আপনাকে অবশ্যই আপনার অনুরোধের অংশ হিসাবে আপনার সামগ্রী ভিডিও ধারণকারী নোডের একটি রেফারেন্স পাস করতে হবে।

দ্রষ্টব্য: প্রদত্ত স্ট্রিম প্যারামিটারগুলি একটি লাইভ পড স্ট্রিমের জন্য। একটি VOD পড স্ট্রিম দিয়ে পরীক্ষা করার জন্য আপনাকে আপনার নিজস্ব টেস্ট স্ট্রিম প্যারামিটার প্রদান করতে হবে।

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

ভিওডি স্ট্রিম পড পরিবেশন

m.testPodServingStream অবজেক্টে, আপনি স্ট্রিম অনুরোধে ব্যবহৃত নেটওয়ার্ক কোড সংরক্ষণ করবেন, যাতে Google Ad Manager একটি স্ট্রিম আইডি প্রদান করতে পারে। এছাড়াও আপনার ম্যানিফেস্ট ম্যানিপুলেশন সার্ভারে ব্যবহারকারী নির্দিষ্ট ম্যানিফেস্ট অ্যাক্সেস করতে ব্যবহৃত ম্যানিফেস্ট URL সংরক্ষণ করুন।

AdUI সমর্থন করতে সক্ষম হতে, যেমন adChoices আইকন, আপনাকে অবশ্যই আপনার অনুরোধের অংশ হিসাবে আপনার সামগ্রী ভিডিও ধারণকারী নোডের একটি রেফারেন্স পাস করতে হবে।

দ্রষ্টব্য: আপনার VOD স্ট্রিম বাস্তবায়ন পরীক্ষা করার জন্য আপনাকে আপনার নিজস্ব নেটওয়ার্ক কোড এবং ম্যানিফেস্ট URL প্রদান করতে হবে।

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA DAI SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

ইভেন্ট শ্রোতা যোগ করুন এবং স্ট্রীম শুরু করুন

লাইভ স্ট্রিম পড পরিবেশন

আপনার স্ট্রীম অনুরোধ করার পরে, শুধুমাত্র কিছু কাজ বাকি আছে: বিজ্ঞাপনের অগ্রগতি ট্র্যাক করতে ইভেন্ট শ্রোতাদের যোগ করুন এবং SDK-এ Roku বার্তা ফরওয়ার্ড করুন। সঠিক বিজ্ঞাপন প্লেব্যাক নিশ্চিত করতে আপনার সমস্ত বার্তা SDK-এ ফরোয়ার্ড করা গুরুত্বপূর্ণ। এটি করতে ব্যর্থ হলে বিজ্ঞাপনের দৃশ্যগুলিকে ভুলভাবে রিপোর্ট করা হয়।

এই ধাপে, আপনি স্ট্রিম আইডি দিয়ে [[STREAMID]] ম্যাক্রো প্রতিস্থাপন করার জন্য একটি ফাংশন যোগ করুন এবং ভিডিও প্লেয়ারে সম্পূর্ণ ম্যানিফেস্ট অনুরোধ URL পাস করুন। এই বাস্তবায়ন এই ধাপে স্ট্রিম আইডি পায়, কিন্তু আপনার VTP ইন্টিগ্রেশনের উপর নির্ভর করে, এই ধাপের আগে এটি উপলব্ধ হতে পারে।

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

ভিওডি স্ট্রিম পড পরিবেশন

আপনার স্ট্রীম অনুরোধ করার পরে, শুধুমাত্র কিছু কাজ বাকি আছে: বিজ্ঞাপনের অগ্রগতি ট্র্যাক করতে ইভেন্ট শ্রোতাদের যোগ করুন এবং SDK-এ Roku বার্তা ফরওয়ার্ড করুন। সঠিক বিজ্ঞাপন প্লেব্যাক নিশ্চিত করতে আপনার সমস্ত বার্তা SDK-এ ফরোয়ার্ড করা গুরুত্বপূর্ণ। এটি করতে ব্যর্থ হলে বিজ্ঞাপনের দৃশ্যগুলিকে ভুলভাবে রিপোর্ট করা হবে৷

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub