IMA डीएआई SDK टूल का इस्तेमाल शुरू करना

IMA SDK की मदद से, मल्टीमीडिया विज्ञापनों को आपकी वेबसाइटों और ऐप्लिकेशन में आसानी से इंटिग्रेट किया जा सकता है. IMA SDK, VAST के मुताबिक किसी भी विज्ञापन सर्वर से विज्ञापनों का अनुरोध कर सकता है. साथ ही, आपके ऐप्लिकेशन में विज्ञापन प्लेबैक को मैनेज कर सकता है. IMA डीएआई SDK टूल की मदद से, ऐप्लिकेशन विज्ञापन और कॉन्टेंट वीडियो के लिए स्ट्रीम का अनुरोध करते हैं, फिर चाहे वह वीओडी (वीडियो ऑन डिमांड) हो या लाइव. इसके बाद, SDK टूल एक साथ वीडियो स्ट्रीम दिखाता है, ताकि आपको अपने ऐप्लिकेशन में विज्ञापन और कॉन्टेंट वीडियो के बीच स्विच करने की प्रोसेस मैनेज न करनी पड़े.

अपनी पसंद का डीएआई सलूशन चुनें

पूरी सेवा पॉड दिखाना

इस गाइड में Roku के लिए IMA डीएआई SDK का इस्तेमाल करके, लाइव या वीओडी स्ट्रीम करने के लिए डीएआई पॉड को चलाने का तरीका बताया गया है.

ध्यान दें: Roku के लिए IMA डीएआई SDK टूल, HLS और DASH दोनों स्ट्रीम के साथ काम करता है. इसमें कोई अंतर नहीं होता.

IMA डीएआई का इस्तेमाल करने के लिए, आपके पास Ad Manager 360 Advanced खाता होना चाहिए. अगर आपके पास Ad Manager खाता है, तो ज़्यादा जानकारी के लिए अपने खाता मैनेजर से संपर्क करें. Ad Manager के लिए साइन अप करने के बारे में जानकारी पाने के लिए, Ad Manager सहायता केंद्र पर जाएं.

ध्यान दें: अन्य प्लैटफ़ॉर्म के साथ इंटिग्रेट करने या IMA क्लाइंट-साइड SDK टूल इस्तेमाल करने के बारे में जानकारी पाने के लिए, इंटरैक्टिव मीडिया विज्ञापन SDK टूल देखें.

IMA डीएआई पॉड दिखाने के बारे में खास जानकारी

IMA डीएआई का इस्तेमाल करके पॉड दिखाने की सुविधा लागू करने में, SDK टूल के दो मुख्य कॉम्पोनेंट शामिल होते हैं, जिनके बारे में इस गाइड में बताया गया है:

• StreamRequest.createPodLiveStreamRequest() / StreamRequest.createPodVodStreamRequest(): यह फ़ंक्शन, Google के विज्ञापन सर्वर से स्ट्रीम के अनुरोध के बारे में बताने वाला ऑब्जेक्ट बनाता है. इन अनुरोधों के लिए नेटवर्क कोड के बारे में बताया जाता है. पॉड लाइव ima.StreamRequest के लिए, कस्टम ऐसेट कुंजी और वैकल्पिक एपीआई पासकोड की भी ज़रूरत होती है.
• StreamManager: एक ऑब्जेक्ट जो वीडियो स्ट्रीम और IMA डीएआई SDK के बीच कम्यूनिकेशन मैनेज करता है. जैसे, ट्रैकिंग पिंग और स्ट्रीम इवेंट पब्लिशर को फ़ॉरवर्ड करना.

इसके अलावा, अपने ऐप्लिकेशन को दिखाने के लिए स्ट्रीम मेनिफ़ेस्ट को वापस पाने के लिए, आपको अपने मेनिफ़ेस्ट में बदलाव करने वाले सर्वर से अनुरोध करना होगा. सटीक प्रोसेस, वीडियो टेक्नोलॉजी पार्टनर (VTP) से VTP में अलग-अलग हो सकती है.

अहम जानकारी: इस गाइड में बताए गए मकसद के लिए, मान लें कि मेनिफ़ेस्ट में बदलाव करने वाले सर्वर को, क्वेरी वैरिएबल के तौर पर पास किए गए स्ट्रीम आईडी के साथ, जीईटी अनुरोध की उम्मीद होती है. अनुरोध के यूआरएल में प्लेसहोल्डर के रूप में, [[STREAMID]] मैक्रो का इस्तेमाल करें और अनुरोध करने से पहले इसे स्ट्रीम आईडी से बदलें. आपका मेनिफ़ेस्ट मैनिप्यूलेशन सर्वर अलग हो सकता है.

ज़रूरी शर्तें

• हमारा काम करने वाला पेज पढ़ें और यह पक्का करें कि इस्तेमाल का आपका सही उदाहरण काम करता हो.
• हमारा Roku सैंपल प्लेयर कोड डाउनलोड करें.
• यह पुष्टि करने के लिए कि आपका डेवलपमेंट सेट अप काम कर रहा है या नहीं, सैंपल प्लेयर कोड को Roku डिवाइस पर डिप्लॉय करें.

अपना वीडियो चलाएं

सैंपल वीडियो प्लेयर, कॉन्टेंट वीडियो को शानदार तरीके से चलाता है. अपने Roku डिवाइस पर सैंपल प्लेयर डिप्लॉय करें, ताकि यह पक्का किया जा सके कि आपका डेवलपमेंट एनवायरमेंट सही तरीके से सेट अप किया गया है.

अपने वीडियो प्लेयर को IMA डीएआई स्ट्रीम प्लेयर में बदलें

स्ट्रीम प्लेयर लागू करने के लिए यह तरीका अपनाएं.

Sdk.xml बनाएं

अपने प्रोजेक्ट में Sdk.xml नाम के MainScene.xml के साथ एक नई फ़ाइल जोड़ें और ये बॉयलरप्लेट जोड़ें:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    ' Your code goes here.
  ]]>
  </script>
  </component>

आपको इस पूरी गाइड में, इन दोनों फ़ाइलों (MainScene.xml और Sdk.xml) में बदलाव करना होगा.

IMA SDK फ़्रेमवर्क लोड करें

फ़्रेमवर्क लोड करने के लिए, manifest और Sdk.xml में ये जोड़ें:

मेनिफ़ेस्ट

bs_libs_required=googleima3

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

  <component name = "imasdk" extends = "Task">
  <interface>
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
  Library "IMA3.brs"
  ]]>
  </script>
  </component>

IMA SDK शुरू करें

IMA SDK के डाइनैमिक ऐड इंसर्शन स्ट्रीम को लोड करने का पहला चरण, IMA SDK को लोड करना और शुरू करना है. नीचे दी गई इमेज, IMA SDK स्क्रिप्ट को शुरू करती है.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
  </interface>
  <script type = "text/brightscript">
  <![CDATA[
    Library "IMA3.brs"
    sub init()
      m.top.functionName = "runThread"
    end sub

    sub runThread()
      if not m.top.IMASDKInitialized
        initializeIMASDK()
      end if
    end sub

    sub initializeIMASDK()
        if m.sdk = invalid
          m.sdk = New_IMASDK()
        end if
        m.top.IMASDKInitialized = true
    end sub
  ]]>
  </script>
  </component>

अब MainScene.xml में यह टास्क शुरू करें और कॉन्टेंट स्ट्रीम लोड करने के लिए कॉल हटाएं.

MainScene.xml

<?xml version="1.0" encoding="utf-8" ?>

<component extends="Scene" initialFocus="myVideo" name="MainScene">
  <script type="text/brightscript">
  <![CDATA[
  function init()
    m.video = m.top.findNode("myVideo")
    m.video.notificationinterval = 1
    runIMASDKTask()
  end function

  function runIMASDKTask()
    m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
    m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
    m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

    m.IMASDKTask.control = "RUN"
  end function

  sub handleIMASDKInitialized()

    ' Follow your manifest manipulator (VTP) documentation to register a user
    ' streaming session if needed.

  end sub

  sub handleIMASDKErrors(message as object)
    print "------ IMA SDK failed  ------"
    if message <> invalid and message.getData() <> invalid
      print "IMA SDK Error ";message.getData()
    end if
  end sub
  ]]>
  </script>
  <children>
    <Video height="720" id="myVideo" visible="false" width="1280"/>
  </children>
</component>

IMA स्ट्रीम प्लेयर बनाएं

इसके बाद, IMA स्ट्रीम प्लेयर बनाने के लिए आपको मौजूदा roVideoScreen का इस्तेमाल करना होगा.

लाइव स्ट्रीम पॉड सर्विंग

लाइव स्ट्रीम के लिए, यह स्ट्रीम प्लेयर तीन कॉलबैक तरीके लागू करता है: streamInitialized, adBreakStarted, और adBreakEnded.

स्ट्रीम लोड होने पर, ट्रिक प्ले को भी बंद कर दें. इससे उपयोगकर्ता, विज्ञापन के लिए ब्रेक शुरू होने वाले इवेंट के शुरू होने से पहले ही, प्री-रोल स्किप नहीं कर पाते.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="urlData" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      m.top.videoNode.enableTrickPlay = false
      m.top.urlData = urlData
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

वीओडी स्ट्रीम पॉड दिखाना

वीओडी स्ट्रीम के लिए, यह स्ट्रीम प्लेयर, कॉलबैक के चार तरीके लागू करता है: streamInitialized, loadUrl, adBreakStarted, और adBreakEnded. streamInitialized कॉलबैक में, पक्का करें कि StreamManager.loadThirdPartyStream() को कॉल किया गया हो. ऐसा न करने पर, SDK loadUrl फ़ंक्शन ट्रिगर नहीं करेगा.

इस चरण में, आपको अपने वीडियो टेक्नोलॉजी पार्टनर (VTP) से ऐसे स्ट्रीम यूआरएल के लिए भी अनुरोध करना होगा जिसके स्ट्रीम आईडी को loadAdPodStream() में लिया गया हो. इसके बाद, विज्ञापनों के पॉड मेनिफ़ेस्ट के साथ StreamManager.loadThirdPartyStream() को कॉल करें और वीटीपी से मिले सबटाइटल भी जोड़ें.

स्ट्रीम लोड होने पर, ट्रिक प्ले को भी बंद कर दें. इससे उपयोगकर्ता, विज्ञापन के लिए ब्रेक शुरू होने वाले इवेंट के शुरू होने से पहले ही, प्री-रोल स्किप नहीं कर पाते.

Sdk.xml

<?xml version="1.0" encoding="utf-8" ?>

  <component name="IMASDKTask" extends="Task">
  <interface>
    <field id="IMASDKInitialized" type="Boolean" />
    <field id="errors" type="stringarray" />
    <field id="adStitchedStreamInfo" type="assocarray" />
    <field id="adPlaying" type="Boolean" />
    <field id="videoNode" type="Node" />
    <field id="streamParameters" type="assocarray" />
  </interface>

  <script type="text/brightscript">
  ...
  sub runThread()
    if not m.top.IMASDKInitialized
      initializeIMASDK()
    end if

    setupPlayerCallbacks()
  end sub
  ...
  sub initializeIMASDK()
    if m.ima = invalid
      ima = New_IMASDK()
      ima.initSdk()
      m.ima = ima
    end if
    m.top.IMASDKInitialized = true
  end sub

  sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
    m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
  end sub

  sub setupPlayerCallbacks()
    m.player = m.ima.createPlayer()
    m.player.top = m.top

    m.player.streamInitialized = function(urlData)
      adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
      loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
    end function

    m.player.loadUrl = function(streamInfo)
      m.top.adStitchedStreamInfo = streamInfo
    end function

    m.player.adBreakStarted = function(adBreakInfo)
      print "------ Ad break started ------"
      m.top.adPlaying = true
      m.top.videoNode.enableTrickPlay = false
    end function

    m.player.adBreakEnded = function(adBreakInfo)
      print "------ Ad break ended ------"
      m.top.adPlaying = false
      m.top.videoNode.enableTrickPlay = true
    end function

  end sub
  </script>
...
</component>

लाइव या वीओडी पॉड दिखाने के लिए स्ट्रीम अनुरोध तैयार करें और उसे एक्ज़ीक्यूट करें

स्ट्रीम प्लेयर बनाने के बाद, स्ट्रीम का अनुरोध किया जा सकता है और उसे लागू किया जा सकता है. इस उदाहरण में, पॉड सर्विंग स्ट्रीम का डेटा दिया गया है जिसे m.testPodServingStream में सेव किया गया है.

लाइव स्ट्रीम पॉड सर्विंग

m.testPodServingStream ऑब्जेक्ट में, ऐसे पैरामीटर सेव करें जो Google Ad Manager को स्ट्रीम की पहचान करने के लिए ज़रूरी हैं. जैसे, नेटवर्क कोड और कस्टम ऐसेट कुंजी. साथ ही, उस मेनिफ़ेस्ट यूआरएल को भी सेव करें जिसका इस्तेमाल आपके मेनिफ़ेस्ट सर्वर को ऐक्सेस करने के लिए किया जाता है. इस मामले में, स्ट्रीम का अनुरोध वापस मिलने के बाद, मेनिफ़ेस्ट यूआरएल में Google स्ट्रीम आईडी जोड़ना ज़रूरी है.

AdUI, जैसे कि adChoices आइकॉन के साथ काम करने के लिए आपको उस नोड को एक रेफ़रंस भी भेजना होगा जिसमें आपके कॉन्टेंट का वीडियो शामिल है.

ध्यान दें: स्ट्रीम के लिए दिए गए पैरामीटर, लाइव पॉड स्ट्रीम के लिए हैं. वीओडी पॉड स्ट्रीम से टेस्ट करने के लिए, आपको अपने टेस्ट स्ट्रीम पैरामीटर देने होंगे.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Test live stream for DAI Pod Serving",
    assetKey: "test-live-stream",
    networkCode: "your-network-code",
    manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
    apiKey: ""
  }
  runIMASDKTask()
end function

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="IMASDKInitialized" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="videoNode" type="Node" />
  <field id="streamParameters" type="assocarray" />
</interface>

...

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)

  ' Set the player object so that the request can trigger the player's
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

वीओडी स्ट्रीम पॉड दिखाना

m.testPodServingStream ऑब्जेक्ट में, स्ट्रीम के अनुरोध में इस्तेमाल किया गया नेटवर्क कोड सेव किया जाएगा. ऐसा इसलिए, ताकि Google Ad Manager एक स्ट्रीम आईडी दे सके. साथ ही, उस मेनिफ़ेस्ट यूआरएल को भी सेव करें जिसका इस्तेमाल उपयोगकर्ता के हिसाब से तय किए गए मेनिफ़ेस्ट को ऐक्सेस करने के लिए किया जाता है. यह यूआरएल आपके मेनिफ़ेस्ट मेनिप्यूलेशन सर्वर पर सेव होता है.

adUI, जैसे कि adChoices आइकॉन के साथ काम करने के लिए आपको अपने अनुरोध के हिस्से के तौर पर, उस नोड को रेफ़र करना होगा जिसमें आपका कॉन्टेंट वीडियो शामिल हो.

ध्यान दें: वीओडी स्ट्रीम लागू करने की जांच के लिए, आपको खुद का नेटवर्क कोड और मेनिफ़ेस्ट यूआरएल देना होगा.

MainScene.xml

sub init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testPodServingStream = {
    title: "Pod Serving VOD Stream",
    networkCode: "your-network-code",
    VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
    subtitleConfig: []
  }
  runIMASDKTask()
end sub

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")

  m.IMASDKTask.control = "RUN"
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
end sub

sub loadAdPodStream()
  request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)

  ' Set the player object so that the request can trigger the player
  ' callbacks at stream initialization or playback events.
  request.player = m.player

  ' Set the video node for the IMA SDK to create ad UI as its child nodes.
  request.adUiNode = m.top.video

  requestResult = m.ima.requestStream(request)
  if requestResult <> invalid
    print "Error requesting stream ";requestResult
    return
  end if

  m.streamManager = invalid
  while m.streamManager = invalid
    sleep(50)
    m.streamManager = m.ima.getStreamManager()
  end while

  if m.streamManager = invalid
    errors = CreateObject("roArray", 1, True)
    invalidStreamManagerError = "Invalid stream manager"
    print invalidStreamManagerError
    errors.push(invalidStreamManagerError)
    m.top.errors = errors
    return
  end if

  if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
    errors = CreateObject("roArray", 1, True)
    print "Stream request returns an error. " ; m.streamManager["info"]
    errors.push(m.streamManager["info"])
    m.top.errors = errors
    return
  end if

  setupStreamManager()
  m.streamManager.start()
end sub

इवेंट लिसनर जोड़ें और स्ट्रीम शुरू करें

लाइव स्ट्रीम पॉड सर्विंग

स्ट्रीम का अनुरोध करने के बाद, आपको सिर्फ़ कुछ काम करने होंगे: विज्ञापन की प्रोग्रेस को ट्रैक करने के लिए, इवेंट लिसनर को जोड़ें और SDK टूल पर Roku मैसेज फ़ॉरवर्ड करें. विज्ञापन को सही तरीके से चलाने के लिए, यह ज़रूरी है कि आप सभी मैसेज SDK टूल पर फ़ॉरवर्ड करें. ऐसा न करने पर, विज्ञापन व्यू को गलत तरीके से रिपोर्ट किया जाएगा.

इस चरण में, [[STREAMID]] मैक्रो को स्ट्रीम आईडी से बदलने के लिए एक फ़ंक्शन भी जोड़ा जाता है. साथ ही, पूरे हो चुके मेनिफ़ेस्ट अनुरोध यूआरएल को वीडियो प्लेयर को भेजा जाता है. इस चरण में, इसे लागू करने पर स्ट्रीम आईडी मिलता है. हालांकि, आपके VTP इंटिग्रेशन के आधार पर, इस चरण से पहले इसे उपलब्ध कराया जा सकता है.

MainScene.xml

function runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end function

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
  manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
  playStream(manifest, adPodStreamInfo.format)
end sub

sub playStream(url as string, format as string)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.testPodservingStream.title
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 And not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

function errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end function

वीओडी स्ट्रीम पॉड दिखाना

स्ट्रीम का अनुरोध करने के बाद, आपको सिर्फ़ कुछ काम करने होंगे: विज्ञापन की प्रोग्रेस को ट्रैक करने के लिए, इवेंट लिसनर को जोड़ें और SDK टूल पर Roku मैसेज फ़ॉरवर्ड करें. सही विज्ञापन प्लेबैक सुनिश्चित करने के लिए यह ज़रूरी है कि आप सभी मैसेज SDK पर फ़ॉरवर्ड करें. ऐसा न करने पर, विज्ञापन व्यू की रिपोर्टिंग गलत तरीके से की जाएगी.

MainScene.xml

sub runIMASDKTask()
  m.IMASDKTask = createObject("roSGNode", "IMASDKTask")

  m.IMASDKTask.streamParameters = m.testPodservingStream
  m.IMASDKTask.videoNode = m.video

  m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
  m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
  m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")

  m.sdkTask.control = "RUN"
end sub

sub loadAdStitchedStream(message as object)
  print "Ad pod stream information ";message
  adPodStreamInfo = message.getData()
end sub

sub playStream(url as string, format as string, subtitleConfig as object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.title = m.testPodservingStream.title
  vidContent.url = url
  vidContent.subtitleConfig = subtitleConfig
  vidContent.streamformat = format
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
end sub

Sdk.xml

sub runThread()
  if not m.top.IMASDKInitialized
    initializeIMASDK()
  end if

  setupPlayerCallbacks()
  loadAdPodStream()
  if m.streamManager <> invalid
    runLoop()
  end if
end sub

sub runLoop()
  m.top.videoNode.timedMetaDataSelectionKeys = ["*"]

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  m.port = CreateObject("roMessagePort")
  m.top.videoNode.observeField("position", m.port)
  m.top.videoNode.observeField("timedMetaData", m.port)
  m.top.videoNode.observeField("timedMetaData2", m.port)
  m.top.videoNode.observeField("state", m.port)

  while True
    msg = wait(1000, m.port)
    if m.top.videoNode = invalid
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.videoNode.position
    if currentTime > 3 and not m.top.adPlaying
      m.top.videoNode.enableTrickPlay = true
    end if
  end while
end sub

sub setupStreamManager()
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub

sub startCallback(ad as object)
  print "Callback from SDK -- Start called - "
end sub

sub firstQuartileCallback(ad as object)
  print "Callback from SDK -- First quartile called - "
end sub

sub midpointCallback(ad as object)
  print "Callback from SDK -- Midpoint called - "
end sub

sub thirdQuartileCallback(ad as object)
  print "Callback from SDK -- Third quartile called - "
end sub

sub completeCallback(ad as object)
  print "Callback from SDK -- Complete called - "
end sub

sub errorCallback(error as object)
  print "Callback from SDK -- Error called - " ; error
  m.errorState = True
end sub