Mit IMA SDKs können Sie Multimedia-Anzeigen ganz einfach in Ihre Websites und Apps einbinden. Mit IMA SDKs können Anzeigen von jedem VAST-kompatiblen Ad-Server angefordert und die Anzeigenwiedergabe in Ihren Apps verwaltet werden. Mit IMA DAI SDKs stellen Apps eine Streamanfrage für Anzeigen- und Contentvideos – entweder VOD oder Livecontent. Das SDK gibt dann einen kombinierten Videostream zurück, sodass Sie in Ihrer App nicht zwischen Anzeigen- und Contentvideo wechseln müssen.
Wählen Sie die gewünschte Lösung für die dynamische Anzeigenbereitstellung aus.
Dynamische Anzeigenbereitstellung mit Komplettservice
In diesem Leitfaden wird erläutert, wie Sie das IMA DAI SDK in eine einfache Videoplayer-App einbinden. Wenn Sie sich das einfache Beispiel von GitHub ansehen oder ein vollständiges Beispielintegration ansehen möchten, laden Sie es herunter.
IMA DAI – Übersicht
Die Implementierung der IMA DAI umfasst zwei wichtige SDK-Komponenten, wie in dieser Anleitung beschrieben:
StreamRequest
: Ein Objekt, das eine Streamanfrage definiert. Streamanfragen können für Video-on-Demand- oder Livestreams erfolgen. In den Anfragen werden eine Content-ID, ein API-Schlüssel oder ein Authentifizierungstoken und weitere Parameter angegeben.StreamManager
: Ein Objekt, das Streams zur dynamischen Anzeigenbereitstellung und Interaktionen mit dem Back-End für die dynamische Anzeigenbereitstellung verarbeitet. Außerdem verarbeitet er Tracking-Pings und leitet Stream- und Anzeigenereignisse an den Publisher weiter.
Voraussetzungen
- Lies dir unsere Kompatibilitätsseite durch, um sicherzugehen, dass dein beabsichtigter Anwendungsfall unterstützt wird.
- Laden Sie unseren Code für den Roku-Beispielplayer herunter.
- Stellen Sie den Beispielcode des Players auf einem Roku-Gerät bereit, um zu prüfen, ob Ihre Entwicklungseinrichtung funktioniert.
Spielen Sie Ihr Video ab.
Mit dem zur Verfügung gestellten Beispielvideoplayer wird automatisch ein Contentvideo wiedergegeben. Stellen Sie den Beispiel-Player auf Ihrem Roku-Player bereit, um sicherzustellen, dass Ihre Entwicklungsumgebung ordnungsgemäß eingerichtet ist.
Videoplayer in einen Streamplayer für die dynamische Anzeigenbereitstellung umwandeln
So implementierst du einen Streamplayer:
Sdk.xml erstellen
Fügen Sie Ihrem Projekt zusammen mit MainScene.xml
eine neue Datei mit dem Namen Sdk.xml
hinzu und fügen Sie den folgenden Textbaustein hinzu:
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
Sie müssen in diesem Leitfaden beide Dateien bearbeiten.
Roku Advertising Framework laden
Das IMA DAI SDK hängt vom Roku Advertising Framework ab. Fügen Sie manifest
und Sdk.xml
Folgendes hinzu, um das Framework zu laden:
Manifest
bs_libs_required=roku_ads_lib,googleima3
Sdk.xml
Library "Roku_Ads.brs"
Library "IMA3.brs"
IMA DAI SDK laden
Der erste Schritt zum Laden des Streams für die dynamische Anzeigenbereitstellung besteht darin, das IMA DAI SDK zu laden und zu initialisieren. Mit folgendem Code wird das Script des IMA DAI SDK geladen.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
...
Sub init()
m.top.functionName = "runThread"
End Sub
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
End Sub
Sub loadSdk()
If m.sdk = invalid
m.sdk = New_IMASDK()
End If
m.top.sdkLoaded = true
End Sub
Starten Sie diese Aufgabe jetzt in MainScene.xml
und entfernen Sie den Aufruf, um den Inhaltsstream zu laden.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
m.sdkTask.control = "RUN"
end function
Sub onSdkLoaded(message as Object)
print "----- onSdkLoaded --- control ";message
End Sub
Sub onSdkLoadedError(message as Object)
print "----- errors in the sdk loading process --- ";message
End Sub
IMA-Stream-Player erstellen
Als Nächstes müssen Sie den vorhandenen roVideoScreen
verwenden, um einen IMA-Stream-Player zu erstellen. Dieser Streamplayer implementiert drei Callback-Methoden: loadUrl
, adBreakStarted
und adBreakEnded
. Deaktivieren Sie außerdem die Trickwiedergabe, wenn der Stream geladen wird. Dadurch wird verhindert, dass Nutzer eine Pre-Roll-Anzeige sofort nach dem Start überspringen, bevor das Ereignis „Werbeunterbrechung gestartet“ ausgelöst wird.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
sdk = m.sdk
m.player = sdk.createPlayer()
m.player.top = m.top
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function
m.player.adBreakEnded = Function(adBreakInfo as Object)
print "---- Ad Break Ended ---- "
m.top.adPlaying = False
m.top.video.enableTrickPlay = true
End Function
End Sub
Streamanfrage erstellen und ausführen
Da Sie jetzt einen Streamplayer haben, können Sie eine Streamanfrage erstellen und ausführen.
Dieses Beispiel enthält Daten für einen Livestream und einen VOD-Stream. Dabei wird der VOD-Stream verwendet, du kannst ihn aber auch live verwenden. Ändere dazu selectedStream
von m.testVodStream
in m.testLiveStream
.
Damit AdUI, z. B. die adChoices-Symbole, unterstützt werden kann, müssen Sie in Ihrer Anfrage auch einen Verweis auf den Knoten übergeben, der Ihr Contentvideo enthält.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testLiveStream = {
title: "Livestream",
assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
apiKey: "",
type: "live"
}
m.testVodStream = {
title: "VOD stream"
contentSourceId: "2548831",
videoId: "tears-of-steel",
apiKey: "",
type: "vod"
}
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
<field id="streamData" type="assocarray" />
<field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
End Sub
Sub loadStream()
sdk = m.sdk
sdk.initSdk()
setupVideoPlayer()
request = {}
streamData = m.top.streamData
if streamData.type = "live"
request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
else if streamData.type = "vod"
request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
else
request = sdk.CreateStreamRequest()
end if
request.player = m.player
request.videoObject = m.top.video
' Required to support UI elements for 'Why This Ad?' and skippability
request.adUiNode = m.top.video
requestResult = sdk.requestStream(request)
If requestResult <> Invalid
print "Error requesting stream ";requestResult
Else
m.streamManager = Invalid
While m.streamManager = Invalid
sleep(50)
m.streamManager = sdk.getStreamManager()
End While
If m.streamManager = Invalid or m.streamManager["type"] <> Invalid or m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "error ";m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
Else
m.top.streamManagerReady = True
addCallbacks()
m.streamManager.start()
End If
End If
End Sub
Event-Listener hinzufügen und Stream starten
Nachdem Sie Ihren Stream angefordert haben, müssen Sie nur noch ein paar Dinge tun: Fügen Sie Event-Listener hinzu, um den Anzeigenfortschritt zu verfolgen, den Stream zu starten und Roku-Nachrichten an das SDK weiterzuleiten.
MainScene.xml
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.observeField("urlData", "urlLoadRequested")
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sub urlLoadRequested(message as Object)
print "Url Load Requested ";message
data = message.getData()
playStream(data.manifest)
End Sub
Sub playStream(url as Object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.videoTitle
vidContent.streamformat = "hls"
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
End Sub
Sdk.xml
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
If m.top.streamManagerReady
runLoop()
End If
End Sub
Sub runLoop()
m.top.video.timedMetaDataSelectionKeys = ["*"]
m.port = CreateObject("roMessagePort")
' Listen to all fields.
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
fields = m.top.video.getFields()
for each field in fields
m.top.video.observeField(field, m.port)
end for
while True
msg = wait(1000, m.port)
if m.top.video = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.video.position
If currentTime > 3 And not m.top.adPlaying
m.top.video.enableTrickPlay = true
End If
end while
End Sub
Function addCallbacks() as Void
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function
Function startCallback(ad as Object) as Void
print "Callback from SDK -- Start called - "
End Function
Function firstQuartileCallback(ad as Object) as Void
print "Callback from SDK -- First quartile called - "
End Function
Function midpointCallback(ad as Object) as Void
print "Callback from SDK -- Midpoint called - "
End Function
Function thirdQuartileCallback(ad as Object) as Void
print "Callback from SDK -- Third quartile called - "
End Function
Function completeCallback(ad as Object) as Void
print "Callback from SDK -- Complete called - "
End Function
Function errorCallback(error as Object) as Void
print "Callback from SDK -- Error called - "; error
m.errorState = True
End Function
Unterstützung für überspringbare Anzeigen hinzufügen (optional)
Damit überspringbare Anzeigen unterstützt werden, müssen Sie dem Player-Objekt des IMA DAI SDKs die Methode seek
hinzufügen, mit der das Video programmatisch in Gleitkommasekunden an der angegebenen Position gesucht wird.
Damit überspringbare Anzeigen unterstützt werden, musst du in deiner Anfrage auch den adUiNode
festlegen.
Sdk.xml
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.seek = Function(timeSeconds as Float)
print "---- SDK requested seek to ----" ; timeSeconds
m.top.video.seekMode = "accurate"
m.top.video.seek = timeSeconds
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function