Mask Kolom

Di Google Ads API, pembaruan dilakukan menggunakan mask kolom. Daftar mask kolom semua kolom yang ingin Anda ubah dengan update, serta kolom tertentu yang tidak ada dalam mask kolom akan diabaikan, bahkan jika dikirim ke server.

Utilitas FieldMasks

Cara yang direkomendasikan untuk membuat mask kolom adalah menggunakan mask kolom bawaan kami utilitas (FieldMasks), yang memungkinkan Anda menghasilkan mask kolom dari objek yang dimodifikasi, bukan membangun mereka dari awal.

Berikut adalah contoh untuk memperbarui kampanye:

my $campaign = Google::Ads::GoogleAds::V17::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V17::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V17::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V17::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Contoh ini pertama-tama membuat objek Campaign dengan menetapkan nama resource-nya menggunakan utilitas ResourceNames, sehingga API mengetahui kampanye mana yang sedang diperbarui.

Contoh ini menggunakan FieldMasks::all_set_fields_of() dalam kampanye untuk secara otomatis menghasilkan mask kolom yang menghitung semua menentukan kolom. Anda kemudian dapat meneruskan mask yang ditampilkan secara langsung ke panggilan update.

FieldMasks::all_set_fields_of() adalah metode yang mudah untuk FieldMasks::field_mask(). Metode ini membandingkan objek yang diteruskan dengan objek kosong dari class yang sama. Pada kode di atas, Anda juga bisa menggunakan

field_mask(Google::Ads::GoogleAds::V17::Resources::Campaign->new({}), $campaign)

bukan all_set_fields_of($campaign).

Membuat mask secara manual

Untuk membuat mask kolom dari awal, pertama-tama Anda akan membuat Google::Ads::GoogleAds::Common::FieldMask , kemudian buat referensi array yang telah diisi dengan nama semua kolom yang ingin Anda ubah, dan terakhir menetapkan referensi array ke {i>field mask<i} Kolom paths.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Memperbarui kolom objek dan subkolomnya

Kolom objek dapat memiliki subkolom (seperti MaximizeConversions yang memiliki tiga: target_cpa_micros, cpc_bid_ceiling_micros, dan cpc_bid_floor_micros); atau pengguna tersebut tidak boleh memiliki sama sekali (misalnya ManualCpm).

Kolom objek tanpa subkolom yang ditentukan

Kolom objek di Perl setara dengan protobuf MESSAGE di klien yang berjalan di gRPC. Saat memperbarui kolom objek yang tidak ditentukan dengan subkolom apa pun, gunakan utilitas FieldMasks untuk membuat mask kolom, yang dijelaskan di atas.

Kolom objek dengan subkolom yang ditentukan

Saat memperbarui kolom objek yang ditentukan dengan subkolom tanpa secara eksplisit mengatur subkolom apa pun pada pesan tersebut, Anda harus menambahkan setiap subkolom objek mutable ke FieldMask, mirip dengan contoh di atas yang membuat {i>field mask<i} dari awal.

Satu contoh umum adalah memperbarui strategi bidding kampanye tanpa menetapkan kolom pada strategi bidding baru. Contoh di bawah ini menunjukkan cara perbarui kampanye untuk menggunakan Strategi bidding MaximizeConversions tanpa menetapkan subkolom apa pun pada strategi bidding.

Dalam hal ini, menggunakan metode all_set_fields_of() dan field_mask() dari Utilitas FieldMasks tidak mencapai sasaran yang dimaksudkan.

Contoh berikut menghasilkan mask kolom yang menyertakan maximize_conversions. Namun, Google Ads API tidak mengizinkan perilaku ini, untuk mencegah pembersihan {i>field <i}secara tidak sengaja dan menghasilkan FieldMaskError.FIELD_HAS_SUBFIELDS {i>error<i}.

Peringatan: Kode berikut menghasilkan error.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V17::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V17::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V17::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V17::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Contoh berikut menunjukkan cara memperbarui kampanye dengan benar untuk menggunakan MaximizeConversions strategi bidding tanpa menetapkan subkolomnya.

Berhasil: Kode di bawah berhasil memperbarui strategi bidding kampanye.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V17::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V17::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V17::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Mengosongkan kolom

Kolom dapat dihapus secara eksplisit dengan menambahkannya ke mask kolom seperti yang ditunjukkan di atas, atau dengan menetapkan kolom ke nilai kosong atau tidak ditentukan. Misalnya, asumsikan Anda memiliki kampanye yang menggunakan strategi bidding MaximizeConversions dan kolom target_cpa_micros ditetapkan dengan nilai yang lebih besar dari 0.

Berhasil: Kode berikut menghapus kolom target_cpa_micros.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V17::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V17::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V17::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V17::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Perhatikan bahwa kolom dengan sub-kolom bertingkat hanya dapat dihapus dengan menghapus masing-masing subkolom individual, seperti yang ditunjukkan di kolom Objek dengan subkolom.