Maski terenowe

W interfejsie Google Ads API aktualizacje są przeprowadzane przy użyciu maski pola. Maska pola zawiera listę wszystkich pól, które chcesz zmienić za pomocą aktualizacji. Wszystkie określone pola, które nie znajdują się w masce pola, są ignorowane, nawet jeśli zostaną wysłane na serwer.

Narzędzie FieldMasks

Zalecamy generowanie masek pól za pomocą naszego wbudowanego narzędzia do tworzenia masek pól (FieldMasks), które umożliwia generowanie masek pól ze zmodyfikowanego obiektu zamiast tworzenia ich od podstaw.

Oto przykład aktualizacji kampanii:

my $campaign = Google::Ads::GoogleAds::V21::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V21::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V21::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V21::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

W tym przykładzie najpierw tworzony jest obiekt Campaign przez ustawienie jego nazwy zasobu za pomocą narzędzia ResourceNames, aby interfejs API wiedział, która kampania jest aktualizowana.

W przykładzie użyto metody FieldMasks::all_set_fields_of() w kampanii, aby automatycznie utworzyć maskę pola, która zawiera wszystkie ustawione pola. Zwróconą maskę możesz następnie przekazać bezpośrednio do wywołania aktualizacji.

FieldMasks::all_set_fields_of() to wygodna metoda dla FieldMasks::field_mask(). Porównuje przekazany obiekt z pustym obiektem tej samej klasy. W podanym wyżej kodzie możesz też użyć

field_mask(Google::Ads::GoogleAds::V21::Resources::Campaign->new({}), $campaign)

zamiast all_set_fields_of($campaign).

Ręczne tworzenie maski

Aby utworzyć maskę pola od zera, najpierw utwórz obiekt Google::Ads::GoogleAds::Common::FieldMask, a następnie utwórz odwołanie do tablicy wypełnionej nazwami wszystkich pól, które chcesz zmienić, i na koniec przypisz odwołanie do tablicy do pola paths maski pola.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Aktualizowanie pól obiektów i ich pól podrzędnych

Pola obiektów mogą mieć pola podrzędne (np. MaximizeConversions, które ma 3 pola podrzędne: target_cpa_micros, cpc_bid_ceiling_micros i cpc_bid_floor_micros) lub nie mieć ich wcale (np. ManualCpm).

Pola obiektów bez zdefiniowanych pól podrzędnych

Pole obiektu w Perlu jest odpowiednikiem protokołu Protobuf MESSAGE w bibliotekach klienta działających w gRPC. Podczas aktualizowania pola obiektu, które nie jest zdefiniowane za pomocą żadnych pól podrzędnych, użyj narzędzia FieldMasks, aby wygenerować maskę pola, jak opisano powyżej.

Pola obiektów ze zdefiniowanymi polami podrzędnymi

Podczas aktualizowania pola obiektu zdefiniowanego za pomocą pól podrzędnych bez wyraźnego ustawiania żadnego z pól podrzędnych w tej wiadomości musisz ręcznie dodać każde z zmiennych pól podrzędnych obiektu do FieldMask, podobnie jak w przykładzie powyżej, który tworzy maskę pola od zera.

Jednym z częstych przykładów jest aktualizacja strategii ustalania stawek w kampanii bez ustawiania żadnych pól w nowej strategii ustalania stawek. Poniższy przykład pokazuje, jak zaktualizować kampanię, aby korzystała ze strategii ustalania stawek MaximizeConversions bez ustawiania żadnych pól podrzędnych w tej strategii.

W takim przypadku użycie metod all_set_fields_of() i field_mask() narzędzia FieldMasks nie przyniesie zamierzonego efektu.

W tym przykładzie generowana jest maska pola, która zawiera maximize_conversions. Interfejs Google Ads API nie zezwala jednak na takie działanie, aby zapobiec przypadkowemu czyszczeniu pól. W takim przypadku zwraca błąd FieldMaskError.FIELD_HAS_SUBFIELDS.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V21::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V21::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V21::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V21::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Poniższy przykład pokazuje, jak prawidłowo zaktualizować kampanię, aby korzystała ze strategii ustalania stawek MaximizeConversions bez ustawiania żadnych jej pól podrzędnych.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V21::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V21::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V21::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Czyszczenie pól

Pola można wyczyścić w sposób jawny, dodając je do maski pola, jak pokazano powyżej, lub ustawiając pole na pustą lub niezdefiniowaną wartość. Załóżmy na przykład, że masz kampanię, która korzysta ze MaximizeConversions strategii ustalania stawek, a pole target_cpa_micros ma wartość większą niż 0.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V21::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V21::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V21::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V21::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Pamiętaj, że pola z zagnieżdżonymi podpola można wyczyścić tylko przez wyczyszczenie każdego z nich osobno, jak pokazano w sekcji Pola obiektów ze zdefiniowanymi podpola.