フィールドマスク

Google Ads API では、更新はフィールドマスクを使用して行われます。フィールドマスクには、更新で変更するすべてのフィールドが一覧表示されます。フィールドマスクにない指定されたフィールドは、サーバーに送信されても無視されます。

FieldMasks ユーティリティ

フィールドマスクを生成するには、組み込みのフィールドマスクユーティリティ（FieldMasks）を使用することをおすすめします。これにより、フィールドマスクをゼロから構築するのではなく、変更されたオブジェクトからフィールドマスクを生成できます。

キャンペーンを更新する例を次に示します。

my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V19::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

この例では、まず ResourceNames ユーティリティを使用してリソース名を設定し、更新対象のキャンペーンを API が認識できるように Campaign オブジェクトを作成します。

この例では、キャンペーンの FieldMasks::all_set_fields_of() メソッドを使用して、設定されたすべてのフィールドを列挙するフィールドマスクを自動的に生成します。返されたマスクを更新呼び出しに直接渡すことができます。

FieldMasks::all_set_fields_of() は FieldMasks::field_mask() のコンビニエンスメソッドです。渡されたオブジェクトを、同じクラスの空のオブジェクトと比較します。上記のコードでは、次のようにすることもできます。

field_mask(Google::Ads::GoogleAds::V19::Resources::Campaign->new({}), $campaign)

all_set_fields_of($campaign) ではなく

マスクを手動で作成する

フィールドマスクを最初から作成するには、まず Google::Ads::GoogleAds::Common::FieldMask オブジェクトを作成し、変更するすべてのフィールドの名前を含む配列参照を作成し、最後に配列参照をフィールドマスクの paths フィールドに割り当てます。

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

オブジェクトフィールドとそのサブフィールドの更新

オブジェクトフィールドにはサブフィールドを含めることができます（target_cpa_micros、cpc_bid_ceiling_micros、cpc_bid_floor_micros の 3 つを含む MaximizeConversions など）。サブフィールドを含めない場合もあります（ManualCpm など）。

サブフィールドが定義されていないオブジェクトフィールド

Perl のオブジェクトフィールドは、gRPC で実行されているクライアントライブラリの protobuf MESSAGE と同等です。サブフィールドで定義されていないオブジェクトフィールドを更新する場合は、上記のように FieldMasks ユーティリティを使用してフィールドマスクを生成します。

定義済みのサブフィールドを含むオブジェクトフィールド

サブフィールドで定義されたオブジェクトフィールドを更新するときに、そのメッセージのサブフィールドを明示的に設定しない場合、上記の例でフィールドマスクを最初から作成する場合と同様に、変更可能なオブジェクトサブフィールドを FieldMask に手動で追加する必要があります。

よくある例としては、新しい入札戦略のフィールドを設定せずに、キャンペーンの入札戦略を更新することがあります。次の例は、入札戦略のサブフィールドを設定せずに MaximizeConversions 入札戦略を使用するようにキャンペーンを更新する方法を示しています。

この場合、FieldMasks ユーティリティの all_set_fields_of() メソッドと field_mask() メソッドを使用しても、目的の目標は達成されません。

次の例では、maximize_conversions を含むフィールドマスクを生成します。ただし、Google 広告 API では、フィールドが誤って消去されないように、この動作は許可されていません。FieldMaskError.FIELD_HAS_SUBFIELDS エラーが発生します。

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

次の例は、MaximizeConversions 入札戦略を使用するようにキャンペーンを適切に更新し、サブフィールドを設定しない方法を示しています。

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

フィールドの消去

フィールドは、上記のようにフィールドマスクに追加するか、フィールドを空の値または未定義の値に設定することで、明示的に消去できます。たとえば、MaximizeConversions 入札戦略を使用するキャンペーンがあり、target_cpa_micros フィールドに 0 より大きい値が設定されているとします。

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

ネストされたサブフィールドを含むフィールドは、サブフィールドが定義されたオブジェクトフィールドで説明されているように、個々のサブフィールドを個別にクリアすることでのみクリアできます。

フィールド マスク