Alan Maskeleri

Google Ads API'de güncellemeler bir alan maskesi kullanılarak yapılır. Alan maskesi, güncellemeyle değiştirmek istediğiniz tüm alanları listeler. Alan maskesinde bulunmayan belirtilen alanlar, sunucuya gönderilmiş olsa bile yoksayılır.

FieldMasks yardımcı programı

Alan maskeleri oluşturmanın önerilen yolu, yerleşik alan maskesi yardımcı programımızı (FieldMasks) kullanmaktır. Bu yardımcı program, sıfırdan oluşturmak yerine değiştirilmiş bir nesneden alan maskeleri oluşturmanıza olanak tanır.

Aşağıda bir kampanyayı güncelleme örneği verilmiştir:

my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V19::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Bu örnekte, API'nin hangi kampanyanın güncellendiğini bilmesi için önce ResourceNames yardımcı programını kullanarak kaynak adını ayarlayarak bir Campaign nesnesi oluşturulur.

Örnekte, tüm ayarlanmış alanları listeleyen bir alan maskesi otomatik olarak oluşturmak için kampanyadaki FieldMasks::all_set_fields_of() yöntemi kullanılmaktadır. Ardından, döndürülen maskeyi doğrudan güncelleme çağrısına iletebilirsiniz.

FieldMasks::all_set_fields_of(), FieldMasks::field_mask() için kolaylık sağlayan bir yöntemdir. İletilen nesnenizi aynı sınıftaki boş bir nesneyle karşılaştırır. Bu nedenle, yukarıdaki kodda

field_mask(Google::Ads::GoogleAds::V19::Resources::Campaign->new({}), $campaign)

yerine all_set_fields_of($campaign).

Manuel olarak maske oluşturma

Alan maskesini sıfırdan oluşturmak için önce bir Google::Ads::GoogleAds::Common::FieldMask nesnesi oluşturur, ardından değiştirmek istediğiniz tüm alanların adlarıyla doldurulmuş bir dizi referansı oluşturur ve son olarak dizi referansını alan maskesinin paths alanına atarsınız.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Nesne alanlarını ve alt alanlarını güncelleme

Nesne alanlarında alt alanlar olabilir (ör. target_cpa_micros, cpc_bid_ceiling_micros ve cpc_bid_floor_micros olmak üzere üç alt alanı olan MaximizeConversions) veya hiç alt alan olmayabilir (ör. ManualCpm).

Tanımlanmış alt alanı olmayan nesne alanları

Perl'deki nesne alanı, gRPC'de çalışan istemci kitaplıklarındaki protobuf MESSAGE ile eşdeğerdir. Alt alanla tanımlanmamış bir nesne alanını güncellerken, yukarıda açıklandığı gibi bir alan maskesi oluşturmak için FieldMasks yardımcı programını kullanın.

Tanımlı alt alanları olan nesne alanları

Alt alanlarla tanımlanan bir nesne alanını, söz konusu mesajdaki alt alanlardan herhangi birini açıkça ayarlamadan güncellerken, değişken nesne alt alanlarının her birini FieldMask alanına manuel olarak eklemeniz gerekir. Bu işlem, sıfırdan bir alan maskesi oluşturan yukarıdaki örneğe benzer.

Sık karşılaşılan bir örnek, yeni teklif stratejisindeki hiçbir alanı ayarlamadan bir kampanyanın teklif stratejisini güncellemektir. Aşağıdaki örnekte, teklif stratejisindeki alt alanlardan hiçbirini ayarlamadan bir kampanyanın MaximizeConversions teklif stratejisini kullanacak şekilde nasıl güncelleneceği gösterilmektedir.

Bu durumda, FieldMasks yardımcı programının all_set_fields_of() ve field_mask() yöntemlerinin kullanılması istenen hedefe ulaşmaz.

Aşağıdaki örnekte, maximize_conversions içeren bir alan maskesi oluşturulmaktadır. Ancak Google Ads API, alanların yanlışlıkla temizlenmesini önlemek için bu davranışa izin vermez ve FieldMaskError.FIELD_HAS_SUBFIELDS hatası oluşturur.

Uyarı: Aşağıdaki kod hata oluşturuyor.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Aşağıdaki örnekte, bir kampanyanın alt alanlarından herhangi birini ayarlamaksızın MaximizeConversions teklif stratejisini kullanacak şekilde nasıl doğru şekilde güncelleneceği gösterilmektedir.

Başarılı: Aşağıdaki kod, kampanya teklif stratejisini başarıyla günceller.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Alanları temizleme

Alanlar, yukarıda gösterildiği gibi alan maskesine ekleyerek veya alanı boş ya da tanımlanmamış bir değere ayarlayarak açıkça temizlenebilir. Örneğin, MaximizeConversions teklif stratejisi kullanan bir kampanyanız olduğunu ve target_cpa_micros alanının 0 değerinden büyük bir değerle ayarlandığını varsayalım.

Başarılı: Aşağıdaki kod, target_cpa_micros alanını temizler.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

İç içe yerleştirilmiş alt alanlara sahip alanların yalnızca Tanımlanmış alt alanlara sahip nesne alanları bölümünde gösterildiği gibi her alt alanın ayrı ayrı temizlenmesiyle temizlenebileceğini unutmayın.