Khẩu trang tại chỗ

Trong API Google Ads, việc cập nhật được thực hiện bằng cách sử dụng mặt nạ trường. Mặt nạ trường liệt kê tất cả các trường mà bạn dự định thay đổi bằng nội dung cập nhật và mọi trường được chỉ định không có trong mặt nạ trường sẽ bị bỏ qua, ngay cả khi được gửi đến máy chủ.

Tiện ích FieldMasks

Bạn nên tạo mặt nạ trường bằng cách sử dụng tiện ích mặt nạ trường tích hợp sẵn (FieldMasks). Tiện ích này cho phép bạn tạo mặt nạ trường từ một đối tượng đã sửa đổi thay vì tạo từ đầu.

Dưới đây là ví dụ về cách cập nhật chiến dịch:

my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => PAUSED,
    networkSettings =>
      Google::Ads::GoogleAds::V19::Resources::NetworkSettings->new({
        targetSearchNetwork => "false"
      })
    });

my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Trước tiên, ví dụ này tạo một đối tượng Campaign bằng cách đặt tên tài nguyên bằng tiện ích ResourceNames để API biết chiến dịch nào đang được cập nhật.

Ví dụ này sử dụng phương thức FieldMasks::all_set_fields_of() trên chiến dịch để tự động tạo mặt nạ trường liệt kê tất cả các trường đã đặt. Sau đó, bạn có thể truyền trực tiếp mặt nạ được trả về đến lệnh gọi cập nhật.

FieldMasks::all_set_fields_of() là một phương thức tiện lợi cho FieldMasks::field_mask(). Phương thức này so sánh đối tượng bạn truyền với một đối tượng trống thuộc cùng một lớp. Vì vậy, trong mã trên, bạn cũng có thể sử dụng

field_mask(Google::Ads::GoogleAds::V19::Resources::Campaign->new({}), $campaign)

thay vì all_set_fields_of($campaign).

Tạo mặt nạ theo cách thủ công

Để tạo mặt nạ trường từ đầu, trước tiên, bạn sẽ tạo một đối tượng Google::Ads::GoogleAds::Common::FieldMask, sau đó tạo một tham chiếu mảng được điền sẵn tên của tất cả các trường mà bạn định thay đổi, và cuối cùng gán tham chiếu mảng cho trường paths của mặt nạ trường.

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
    paths => ["status", "name"]
  });

Cập nhật các trường đối tượng và trường con của các trường đó

Các trường đối tượng có thể có trường con (chẳng hạn như MaximizeConversions có ba trường con: target_cpa_micros, cpc_bid_ceiling_micros và cpc_bid_floor_micros); hoặc không có trường con nào (chẳng hạn như ManualCpm).

Các trường đối tượng không có trường con được xác định

Trường đối tượng trong Perl tương đương với MESSAGE protobuf trong thư viện ứng dụng chạy trên gRPC. Khi cập nhật một trường đối tượng không được xác định bằng bất kỳ trường con nào, hãy sử dụng tiện ích FieldMasks để tạo mặt nạ trường, như mô tả ở trên.

Trường đối tượng có các trường con được xác định

Khi cập nhật một trường đối tượng được xác định bằng các trường con mà không đặt rõ ràng bất kỳ trường con nào trên thông báo đó, bạn phải thêm từng trường con đối tượng có thể thay đổi vào FieldMask theo cách thủ công, tương tự như ví dụ ở trên tạo một mặt nạ trường từ đầu.

Một ví dụ phổ biến là cập nhật chiến lược đặt giá thầu của chiến dịch mà không đặt bất kỳ trường nào trên chiến lược đặt giá thầu mới. Ví dụ bên dưới minh hoạ cách cập nhật chiến dịch để sử dụng chiến lược giá thầu MaximizeConversions mà không cần đặt bất kỳ trường phụ nào trên chiến lược giá thầu.

Trong trường hợp này, việc sử dụng các phương thức all_set_fields_of() và field_mask() của tiện ích FieldMasks sẽ không đạt được mục tiêu dự kiến.

Ví dụ sau đây tạo một mặt nạ trường bao gồm maximize_conversions. Tuy nhiên, API Google Ads không cho phép hành vi này để tránh vô tình xoá các trường và tạo lỗi FieldMaskError.FIELD_HAS_SUBFIELDS.

Cảnh báo: Mã sau đây sẽ gây ra lỗi.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new()
    });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask will include 'maximize_conversions',
# which will produce a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

# Sends the operation in a mutate request that will result in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
    customerId => $customer_id,
    operations => [$campaign_operation]
  });

Ví dụ sau đây minh hoạ cách cập nhật đúng cách một chiến dịch để sử dụng chiến lược đặt giá thầu MaximizeConversions mà không cần đặt bất kỳ trường phụ nào.

Thành công: Mã bên dưới đã cập nhật thành công chiến lược đặt giá thầu của chiến dịch.

# Creates a campaign with the proper resource name.
my $campaign = Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    )
  });

# Creates a field mask from the existing campaign and adds all of the fields
# on the MaximizeConversions bidding strategy to the field mask. Because these
# fields are included in the field mask but excluded from the campaign object,
# the Google Ads API will set the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# Learn more about standard and portfolio bidding strategies here:
# https://developers.google.com/google-ads/api/docs/campaigns/bidding/assign-strategies
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => $field_mask
  });

Xoá trường

Bạn có thể xoá các trường một cách rõ ràng bằng cách thêm các trường đó vào mặt nạ trường như minh hoạ ở trên hoặc bằng cách đặt trường thành giá trị trống hoặc không xác định. Ví dụ: giả sử bạn có một chiến dịch sử dụng chiến lược đặt giá thầu MaximizeConversions và trường target_cpa_micros được đặt giá trị lớn hơn 0.

Thành công: Mã sau đây sẽ xoá trường target_cpa_micros.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V19::Resources::Campaign->new({
    resourceName => Google::Ads::GoogleAds::V19::Utils::ResourceNames::campaign(
      $customer_id, $campaign_id
    ),
    maximizeConversions => Google::Ads::GoogleAds::V19::Resources::MaximizeConversions->new({
      targetCpaMicros => 0
    })
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask, which will include 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V19::Services::CampaignService::CampaignOperation->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign)
  });

Xin lưu ý rằng bạn chỉ có thể xoá các trường có trường con lồng nhau bằng cách xoá từng trường con riêng lẻ, như minh hoạ trong phần Trường đối tượng có trường con được xác định.