इस पेज का अनुवाद Cloud Translation API से किया गया है.

Google Ads क्वेरी भाषा व्याकरण

इस पेज पर, Google Ads क्वेरी लैंग्वेज के व्याकरण का रेफ़रंस दिया गया है. क्वेरी स्ट्रक्चर के बारे में ज़्यादा जानने के लिए, क्वेरी स्ट्रक्चर देखें.

यहां Google Ads Query Language के व्याकरण का रेफ़रंस दिया गया है. यह रेफ़रंस रेगुलर एक्सप्रेशन नोटेशन में है:

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

?का मतलब है कि यह एक वैकल्पिक एलिमेंट है
* का मतलब है कि यह शून्य या इससे ज़्यादा बार हो सकता है; + का मतलब है कि यह एक या इससे ज़्यादा बार हो सकता है
(xxxxxx) का मतलब है कि यह एक ग्रुप है
[a-z0-9] का मतलब है कि यह वर्णों की रेंज है
| का मतलब है "या"

नियम और सीमाएं

REGEXP_MATCH ऑपरेटर, RE2 सिंटैक्स का इस्तेमाल करता है.
LIKE ऑपरेटर का इस्तेमाल करके, लिटरल [, ], % या _ से मैच करने के लिए, वर्ण को स्क्वेयर ब्रैकेट में रखें. उदाहरण के लिए, यहां दी गई शर्त, [Earth_to_Mars] से शुरू होने वाली सभी campaign.name वैल्यू से मेल खाती है:
```
campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
```
LIKE ऑपरेटर का इस्तेमाल सिर्फ़ स्ट्रिंग फ़ील्ड पर किया जा सकता है, ऐरे पर नहीं.