Tata Bahasa Kueri Google Ads

Video: Validating Queries

Halaman ini berisi referensi tata bahasa Google Ads Query Language. Untuk mengetahui detail struktur kueri, lihat Struktur Kueri.

Berikut referensi tata bahasa Google Ads Query Language (dalam notasi ekspresi reguler):

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

?menunjukkan elemen opsional
* berarti nol atau lebih; + berarti satu atau lebih
(xxxxxx) menunjukkan pengelompokan
[a-z0-9] menandakan rentang karakter
| berarti "atau"

Aturan dan batasan

• Operator REGEXP_MATCH menggunakan sintaksis RE2.

• Untuk mencocokkan [, ], %, atau _ literal menggunakan operator LIKE, apit karakter dalam tanda kurung siku. Misalnya, kondisi berikut cocok dengan semua nilai campaign.name yang diawali dengan [Earth_to_Mars]:

  campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
  

• Operator LIKE hanya dapat digunakan pada kolom string, bukan array.