Грамматика языка запросов Google Рекламы

Видео: Проверка запросов

Вот справочник по грамматике языка запросов Google Ads (в нотации регулярных выражений):

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

? указывает на необязательный элемент
* означает ноль или больше; + означает один или больше
(xxxxxx) указывает на группировку
[a-z0-9] обозначает диапазоны символов
| означает «или»

Правила и ограничения

• Оператор REGEXP_MATCH использует синтаксис RE2 .

• Чтобы сопоставить литерал [ , ] , % или _ с помощью оператора LIKE , заключите символ в квадратные скобки. Например, следующее условие соответствует всем значениям campaign.name , начинающимся с [Earth_to_Mars] :

  campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
  

• Оператор LIKE можно использовать только для строкового поля, но не для массива.