ไวยากรณ์ภาษาในการค้นหาของ Google Ads

วิดีโอ: การตรวจสอบคําค้นหา

ต่อไปนี้เป็นข้อมูลอ้างอิงเกี่ยวกับไวยากรณ์ภาษาคําค้นหาของ Google Ads (ในรูปแบบนิพจน์ทั่วไป)

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

? หมายถึงเอลิเมนต์ที่ไม่บังคับ
* หมายถึง 0 รายการขึ้นไป + หมายถึง 1 รายการขึ้นไป
(xxxxxx) หมายถึงการจัดกลุ่ม
[a-z0-9] หมายถึงช่วงอักขระ
| หมายถึง "หรือ"

กฎและข้อจำกัด

  • ตัวดำเนินการ REGEXP_MATCH ใช้ไวยากรณ์ RE2

  • หากต้องการจับคู่ค่าตามตัวอักษร [, ], % หรือ _ โดยใช้โอเปอเรเตอร์ LIKE ให้ใส่วงเล็บเหลี่ยมล้อมรอบอักขระ ตัวอย่างเช่น เงื่อนไขต่อไปนี้จะจับคู่กับค่า campaign.name ทั้งหมดที่ขึ้นต้นด้วย [Earth_to_Mars]

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • โอเปอเรเตอร์ LIKE ใช้ได้กับช่องสตริงเท่านั้น ไม่ใช่อาร์เรย์

ก่อนหน้า
ภาพรวม
ถัดไป
โครงสร้างการค้นหา