আপনার পছন্দের ভাষায় কন্টেন্ট অনুবাদ করতে Google তার AI প্রযুক্তি ব্যবহার করে। AI-এর মাধ্যমে করা অনুবাদে ভুল থাকতে পারে।

Google Ads কোয়েরি ল্যাঙ্গুয়েজ গ্রামার

এই পৃষ্ঠায় Google Ads কোয়েরি ল্যাঙ্গুয়েজ গ্রামার রেফারেন্স আছে। কোয়েরি স্ট্রাকচার সংক্রান্ত বিবরণের জন্য, কোয়েরি স্ট্রাকচার দেখুন।

ব্যাকরণ রেফারেন্স

এখানে Google Ads কোয়েরি ল্যাঙ্গুয়েজ গ্রামার রেফারেন্স (রেগুলার এক্সপ্রেশন নোটেশনে) দেওয়া হল:

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

? দিয়ে ঐচ্ছিক এলিমেন্ট বোঝানো হয়।
* মানে শূন্য বা তার বেশি; + মানে এক বা তার বেশি।
(...) গ্রুপিং নির্দেশ করে, যেখানে "(" এবং ")" আক্ষরিক প্রথম বন্ধনী নির্দেশ করে।
[a-z0-9] অক্ষরের রেঞ্জ বোঝায় এবং [^...] তালিকাভুক্ত অক্ষর ছাড়া অন্য যেকোনও অক্ষর বোঝায়।
|-এর অর্থ হল "অথবা"।

নিয়ম ও সীমাবদ্ধতা

GoogleAdsService কোয়েরি করার সময় FromClause প্রয়োজন এবং GoogleAdsFieldService কোয়েরি করার সময় অবশ্যই বাদ দিতে হবে।
WhereClause শুধুমাত্র AND-এর সাথে শর্তাবলী একত্রিত করার সুবিধা দেয়। লজিক্যাল OR কাজ করে না; এর পরিবর্তে IN বা REGEXP_MATCH অপারেটর ব্যবহার করুন।
REGEXP_MATCH অপারেটর RE2 সিনট্যাক্স ব্যবহার করে।
LIKE অপারেটর ব্যবহার করে আক্ষরিক [, ], % বা _-এর সাথে ম্যাচ করতে, অক্ষরটি থার্ড ব্র্যাকেটের মধ্যে রাখুন। যেমন, নিম্নলিখিত শর্তটি [Earth_to_Mars] দিয়ে শুরু হওয়া সব campaign.name ভ্যালুর সাথে ম্যাচ করে:
```
campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
```
LIKE অপারেটর শুধুমাত্র স্ট্রিং ফিল্ডে ব্যবহার করা যাবে, অ্যারেতে নয়।